!*****************************************
! Versuch: 	Zugversuch-Validierung
! Bearbeiter:	
!*****************************************
!*****************************************

! Aktuellen Prozess beenden
finish

! Speicher leeren und Ansys neustarten
/clear,start

! Eigene Parameter definieren

!Angaben in [N/mm²]
!Material 
EM=210000 	!E-Modul Material    
FY1=690		!Streckgrenze Material 1  
FM1=880		!Zugestigkeit
EM1=0.07	!Dehnung bei Zugfestigkeit
FB1=970		!Bruchspannung
EB1=0.14	!Bruchdehnung
v=0.30		!Querdehnzahl

!Angaben in [N/mm]
!Belastung [Druck=positiv ; Zug=negativ]
q=-489	!Belastung
!*****************************************
/prep7			!Preprozessor starten
ET,1,186		!Solid186


!*****************************************
!Material
TYPE,1
 
MPTEMP,1,0 			!Temperatur
MPDATA,EX,1,,EM 
MPDATA,EY,1,,EM 
MPDATA,EZ,1,,EM 
MPDATA,PRXY,1,,v		!Querdehnzahl	 
TB,PLASTIC,1,1,3,MISO  		!Multilineares Verhalten
TBTEMP,0			!Bezugstemperatur
TBPT,DEFI,0,FY1			!plastische Dehnung, Spannung
TBPT,DEFI,EM1,FM1
TBPT,DEFI,EB1,FB1


!*****************************************
!Geometrie
!Keypoints definieren

k,1,0,0,0
k,2,5,0,0
k,3,10,20,0
k,4,0,20,0
k,5,0,50,0
k,6,10,50,0

k,13,10,-20
k,14,0,-20,0
k,15,0,-50,0
k,16,10,-50,0

k,101,0,0,5
k,102,5,0,5
k,103,10,20,5
k,104,0,20,5
k,105,0,50,5
k,106,10,50,5

k,113,10,-20,5
k,114,0,-20,5
k,115,0,-50,5
k,116,10,-50,5

v,1,2,102,101,4,3,103,104
v,4,3,103,104,5,6,106,105
v,1,2,102,101,14,13,113,114
v,14,13,113,114,15,16,116,115


!Netzgenerierung

mshape,1,3D	!Netzart bestimmen
TYPE,1		!Elementtyp 1 auswählen

mat,1		!Material 1 aktiv setzen
secnum,1	!Elementnummer
esize,4		!Elementgröße
vsel,s,VOLU,,2	!Fläche 1 aktiv setzen
vsel,a,VOLU,,4
vmesh,all	!vernetzen

esize,2
vsel,s,VOLU,,1
vsel,a,VOLU,,3
vmesh,all


!*****************************************
!Lagerungsbedingungen


asel,s,AREA,,21
DA,all,UY 	!Freiheitsgrade festsetzen


asel,s,AREA,,5
asel,a,AREA,,10
asel,a,AREA,,15
asel,a,AREA,,20
DA,all,UX
DA,all,UZ
!*****************************************
!Lasten

asel,s,AREA,,11 		!Wähle Linie 6
SFA,all,,Press,q	!Streckenlast
AUTOTS,ON		!autmatische Zeitschrittwahl
NSUBST,100,1000,10	!Lastschritte

!*****************************************
ksel,s,KP,,all
lsel,s,LINE,,all
asel,s,AREA,,all
allsel
finish		!Preprozessor beenden

!*****************************************
!*****************************************

/solu				!Solution starten
nlgeom,on			!große Verschiebungen
PRED,on				!Prädikator einschalten
Solve	
finish				!Beende Solution


!*****************************************
!*****************************************
/POST1 				!Postprozessor starten
PLNSOL,EPPL,Y, 0,1.0		!plastische Verformungen ausgeben
/EXPAND,2,POLAR,HALF,,90
/replot
finish				!Postprozessor beenden