fini	
/clear
/title, 4-10-4 Winddruck

!Bestimmung der Variablen
x1=0
x2=0.004	!m
x3=0.014	!m
x4=0.018	!m

x5=-0.01	!m
x6= 0.009	!m

y1=0		!m
y2=0.5		!m
y3=1		!m

y5 =0.04	!m
y11=0.001	!m
y12=0.999	!m

gro=0.001	!m
delta=0.000001


!Materialeigenschaften für Strukturelementanalyse
emodGLAS=70000000000	!N/m²	!Material 1
ausd=9e-6				!1/K
quer=0.23				!-

emodSZR=10000000000000000	!N/m²		!Material 2
querlft=0.4999		!-

dichte=1.2		!kg/m³		!Material 3 (Fluid)

p=1000		!N/m²
t1=283.15	!K
t2=303.15	!K


/prep7

!geometrische Struktur

k,   1,x1,y1
k,   2,x1,y2
k,   3,x1,y3
k,   4,x2,y1
k,1004,x2,y1		!Knoten doppelt für Gelenk
k,   5,x2,y2
k,   6,x2,y3
k,1006,x2,y3		!Knoten doppelt für Gelenk
k,   7,x3,y1
k,1007,x3,y1		!Knoten doppelt für Gelenk
k,   8,x3,y2
k,   9,x3,y3
k,1009,x3,y3		!Knoten doppelt für Gelenk
k,  10,x4,y1
k,  11,x4,y2
k,  12,x4,y3

k, 101,x1,y11
k, 103,x1,y12
k, 104,x2,y11
k,1104,x2,y11		!Knoten doppelt für Gelenk
k, 107,x3,y11
k,1107,x3,y11		!Knoten doppelt für Gelenk
k, 106,x2,y12
k,1106,x2,y12		!Knoten doppelt für Gelenk		
k, 109,x3,y12
k,1109,x3,y12		!Knoten doppelt für Gelenk
k, 110,x4,y11
k, 112,x4,y12

n,100,x5,y5		!"Spacenode"
n,200,x6,y2		!"Pressurenode"

a,1,101,104,4	!Scheibe 1
a,101,2,5,104
a,2,103,106,5
a,103,3,6,106

a,1004,1104,1107,1007	!SZR
a,1106,1006,1009,1109

a,7,107,110,10	!Scheibe 2
a,107,8,11,110
a,8,109,112,11
a,109,9,12,112

!FE-Modell

et,1,plane182
esize,gro

et,3,plane182
esize,gro

et,4,plane182
esize,gro

et,11,hsfld241
keyopt,11,1,0		!DOF ux und uy für I+J, hydraulischer Druck für L
keyopt,11,6,1		!inkompressibles Volumen 

mp,ex,1,emodGLAS		
mp,prxy,1,quer
mp,alpx,1,ausd

mp,ex,2,emodSZR
mp,prxy,2,querlft

mp,dens,3,dichte

mat,1							!Scheibe 1
type,1
asel,s,loc,x,x2/2
amesh,all
asel,all

mat,1							!Scheibe 2
type,3
asel,s,loc,x,x3+(x4-x3)/2
amesh,all
asel,all

mat,2							!Dichtung SZR oben und unten
type,4
asel,s,loc,y,y11/2
asel,a,loc,y,y12+(y3-y12)/2
amesh,all
asel,all

mat,3							!Fluid
type,11
lsel,s,loc,x,x2
lsel,u,loc,y,y11/2
lsel,u,loc,y,y12+(y3-y12)/2
nsll,s,1
esel,s,type,,1
esurf,200

type,11
lsel,s,loc,x,x3
lsel,u,loc,y,y11/2
lsel,u,loc,y,y12+(y3-y12)/2
nsll,s,1
esel,s,type,,3
esurf,200

type,11
lsel,s,loc,y,y11
lsel,r,loc,x,x2+(x3-x2)/2
nsll,s,1
esel,s,type,,4
esurf,200

type,11
lsel,s,loc,y,y12-delta,y12+delta
lsel,r,loc,x,x2+(x3-x2)/2
nsll,s,1
esel,s,type,,4
esurf,200

lsel,all
nsel,all
esel,all

nsel,s,loc,x,x2
nsel,r,loc,y,y11
cp,1,ux,all

nsel,s,loc,x,x2
nsel,r,loc,y,y11
cp,2,uy,all

nsel,s,loc,x,x2
nsel,r,loc,y,y12-delta,y12+delta
cp,3,ux,all

nsel,s,loc,x,x2
nsel,r,loc,y,y12-delta,y12+delta
cp,4,uy,all

nsel,s,loc,x,x3
nsel,r,loc,y,y11
cp,5,ux,all

nsel,s,loc,x,x3
nsel,r,loc,y,y11
cp,6,uy,all

nsel,s,loc,x,x3
nsel,r,loc,y,y12-delta,y12+delta
cp,7,ux,all

nsel,s,loc,x,x3
nsel,r,loc,y,y12-delta,y12+delta
cp,8,uy,all

nsel,all

save
finish

/solu

!Randbedingungen
nsel,s,loc,y,y1
nsel,a,loc,y,y3-delta,y3+delta
nsel,r,loc,x,x2/2
esel,s,type,,4
nsel,u,ext
d,all,ux

nsel,s,loc,y,y1
nsel,a,loc,y,y3-delta,y3+delta
nsel,r,loc,x,x3+x2/2
esel,s,type,,4
nsel,u,ext
d,all,ux

nsel,s,loc,y,y1
nsel,r,loc,x,x3+x2/2
esel,s,type,,4
nsel,u,ext
d,all,uy

nsel,s,loc,y,y1
nsel,r,loc,x,x2/2
esel,s,type,,4
nsel,u,ext
d,all,uy

lsel,all
nsel,all
esel,all

nsel,s,loc,x,x1				!Aufbringen Winddruck
sf,all,pres,p

nsel,all

nlgeom,on

solve

save
finish