Hallo Fedora,
Ich arbeite ähnlich wie du es beschrieben hast. Habe eine VM mit TC server und Client. Mehr ist auch gar nicht nötig, um mit mehreren dann in dieser VM zu arbeiten.
Voraussetzung ist, dass sich alle PC/Notebook im selben Netz befinden und die gestartete VM als PC von allen PC/Notebooks gesehen wird (ping test).
Auf einem PC/Notebook die VM starten und dann via Batch auf allen PC/Notebooks NX im "managed mode" starten (TC in der VM muss natürlich die notwendigen Lizenzen haben).
Vorteil ist, das man keinerlei Software auf den Clienten installieren muss, Nachteil, dass man kein echtes TC startet auf dem Clienten startet und somit auch nicht dir Funktionalität hat, die TC bietet. Man hat dann nur den TC Navigator in NX. Aber der reicht ja schon für viele Dinge.
Hier mal ein Batch, welches ich nutze (müsste dann natürlich auf die Gegebenheiten (Drive Mounts und Variablen) angepasst werden):
@ECHO OFF
echo.
echo -----------------------------------------------
echo Running 2-Tier Setup Script
echo -----------------------------------------------
:: -------------------------------------------------
: MOUNT_DRIVES
:: -------------------------------------------------
echo - Checking Drive Mounts
if exist Y:\tcdata_tc91 goto UNSET_VARIABLES
if exist Y: net use Y: /delete /yes
net use Y: \\tc91\tc /user:tc91\ntpriv Tc91beta2 /persistent:no
if %ERRORLEVEL% neq 0 goto ERROR_DRIVE_MOUNT
:: -------------------------------------------------
: UNSET_VARIABLES
:: -------------------------------------------------
echo - Unsetting Variables
set TC_ROOT=
set TC_DATA=
set JAVA_HOME=
set FMS_HOME=
set UGII_TC_CHECKING_LEVEL=
set UGII_UGMGR_COMMUNICATION=
set UGII_UGMGR_HTTP_URL=
:: -------------------------------------------------
:SET_VARIABLES
:: -------------------------------------------------
echo - Setting Variables
set TC_ROOT=Y:\root
set TC_DATA=Y:\tcdata_tc91
set JAVA_HOME=%TC_ROOT%\portal\jre
set FMS_HOME=%TC_ROOT%\tccs
set FCC_JAVA=%TC_ROOT%\portal\jre
set TCCS_JAVA=%TC_ROOT%\portal\jre
:: -------------------------------------------------
:START_FCC
:: -------------------------------------------------
echo - Starting FCC
echo.
%FMS_HOME%\bin\fccstat -restart
if %ERRORLEVEL% neq 0 goto ERROR_FCC
%FMS_HOME%\bin\fccstat -clear
:: -------------------------------------------------
:SUMMARY
:: -------------------------------------------------
echo.
echo.
echo ------------------------
echo Summary
echo ------------------------
echo TC_ROOT %TC_ROOT%
echo TC_DATA %TC_DATA%
echo JAVA_HOME %JAVA_HOME%
echo FMS_HOME %FMS_HOME%
echo UGII_UGMGR_COMMUNICATION %UGII_UGMGR_COMMUNICATION%
echo UGII_UGMGR_HTTP_URL %UGII_UGMGR_HTTP_URL%
echo.
echo.
echo *************************************************
echo *************************************************
echo Please do not modify the network connection type
echo to "Bridged" when running the virtualtc VM.
echo This impacts everyone running TCIN VM.
echo *************************************************
echo *************************************************
echo.
echo If your FCC has succesfully started, run the following on the
echo command line to start NX in managed mode as user eng_user1 with password 1234:
echo ugraf -pim=yes -u=eng_user1 -p=1234
goto THE_END
:: -------------------------------------------------
::ERROR
:: -------------------------------------------------
:ERROR_DRIVE_MOUNT
echo Drive Mount Failed
echo - Check to make sure the VM is running.
goto THE_END
:ERROR_FCC
echo FCC Failed to Start
echo - Check hosts file for correct virtualtc IP address
goto THE_END
::ERROR_CREATE_DIR
:: echo Create Directories Failed
:: echo - Check write permissions on %TEMP%
:: goto THE_END
:THE_END
Grüße
Felix
Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP
Foren auf CAD.de (alle Foren)
| 
