---

Hallo, ich habe eine Anfrage.
Ich möchte per ilogic als externe Regel, einen Durchlauf starten, bei dem ich die Regel in der höchsten oder in einer Baugruppe auslöse und alle enthaltenen Baugruppen und oder Bauteile durchläuft.
Es sollen zwei benutzerdefinierte iPropertie erstellt werden "Artikelnummer", die wiederum aus dem benutzerdefinierten iPropertie "Auftragsnummer" 24A444 beispielsweise und der Bauteilnummer der Baugruppe oder vom Bauteil besteht.
Jedes Bauteil und jede Baugruppe muss durchlaufen werden und die entsprechende Nummer erstellt werden.
Geht sowas überhaupt?
Ich arbeite mit inventor 2024.
Vielen Dank im voraus.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Willkommen im Forum 

Zu deiner Frage, ja das geht. Und jetzt? Schätze wir sollen machen. Mal als Anfang zum Testen:

Code:

---

Option Explicit On

Private Sub Main()

Dim oApp As Inventor.Application = ThisApplication

If Not oApp.ActiveEditDocument.DocumentType = kAssemblyDocumentObject Then
    MsgBox ("Funktion nur in Baugruppen verügbar. Abbruch")
    Exit Sub
End If

Dim oAssDoc As AssemblyDocument = oApp.ActiveEditDocument

Dim sAuftragsnummer As String
Dim oProp As Inventor.Property

For Each oProp In oAssDoc.PropertySets(4)
    If oProp.Name = "Auftragsnummer" Then
        sAuftragsnummer = oProp.Value
        Exit For
    End If
Next

If sAuftragsnummer = String.Empty Then
sAuftragsnummer = InputBox("Auftragsnummer eingeben:", "iLogic SetProps")
If sAuftragsnummer = String.Empty Then
Exit Sub 'User cancelled Input
Else
oAssDoc.PropertySets(4).Add(sAuftragsnummer, "Auftragsnummer")
End If
End If

Try
oAssDoc.PropertySets(4).Item("Artikelnummer").Value = sAuftragsnummer & "-" & oAssDoc.PropertySets(3).Item("Part Number").Value
Catch
oAssDoc.PropertySets(4).Add(sAuftragsnummer & "-" & oAssDoc.PropertySets(3).Item("Part Number").Value, "Artikelnummer")
End Try

Dim oRefedDoc As Document
For Each oRefedDoc In oAssDoc.AllReferencedDocuments
If oRefedDoc.IsModifiable=True Then
Try
oRefedDoc.PropertySets(4).Item("Auftragsnummer").Value = sAuftragsnummer
Catch
oRefedDoc.PropertySets(4).Add(sAuftragsnummer, "Auftragsnummer")
End Try
Try
oRefedDoc.PropertySets(4).Item("Artikelnummer").Value = sAuftragsnummer & "-" & oRefedDoc.PropertySets(3).Item("Part Number").Value
Catch
oRefedDoc.PropertySets(4).Add(sAuftragsnummer & "-" & oRefedDoc.PropertySets(3).Item("Part Number").Value, "Artikelnummer")
End Try
end if
Next
   
End Sub

---

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo, dass ist super. Der von Ihnen erstellte Sub funktioniert bis jetzt, genau wie gewünscht. Vielen Dank dafür.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

@rkaush
Das Makro selbst ist super.
@RP4711
Die Sinnhaftigkeit ist eher zweifelhaft.
Das kann ja nur für Baugruppen eingesetzt werden, wo kein einziges Teil je in anderen Baugruppen wiederverwendet wird oder wurde.
Das ist allerdings nur für Prototypenbau oder sonstige Unikate für mich vorstellbar.
Ansonsten kollidiert das dann mit Freigaben/Dokumentenmanagement. Oder werden die Artikelnummern immer durch das erstmalige neue Auftreten in einer Baugruppe festgelegt?
Mich würde der Anwendungsfall interessieren - vielleicht kannst du das ja erklären.

------------------
Mit freundlichem Gruß

Udo Hübner
www.CAD-Huebner.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Ich kann so einen Anwendungsfall skizzieren. Es gibt Firmen, die fertigen kundenspezifisch. Die Losgröße für jedes Teil ist gleich 1. Die mögliche Variantenzahl geht dabei gegen unendlich. Es macht keinen Sinn dort an Wiederverwendung denken. Die Suche nach einem wiederverwendbaren Teil würde ewig dauern und nur seltenst zum Erfolg führen. Allein schon die Erfassung der relevanten Vergleichsparameter (irgendwer muss ja irgendwie der Suche sagen wonach sie suchen soll) könnte schnell länger dauern als neu modellieren. Insbesondere, wenn Teile sich in vielen nichtgeometrischen Parametern unterscheiden können. Man könnte zwar das modellierte Teil davon unabhängig machen, sprich die Teilenummer bestimmt nur die geometrische Form, aber einfacher wird es meiner Meinung dadurch auch nicht unbedingt.
Bei solchen Konstrukten fehlt eigentlich nur noch eine KI. 

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP