---

Hallo zusammen, irgendwie finde ich keinen Auswahlfilter für Maß in einer Skizze. Denn ich will alle mit einem Schlag markieren und löschen. Geht so was? herzlichen Dank Sascha

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Sascha,

falls es wirklich keinen Filter dazu gibt kannst du dieses Makro ausprobieren:

Code:

---

' Macro removes all dimensions from the active sketch
' Needs the active document and the sketch in edit mode
' FX64 daywa1k3r, Igor Zupevc, 16.07.2014
Sub DeleteAllSketchDimensions()
    If ThisApplication.ActiveDocument Is Nothing Then
        MsgBox "No active document found", vbCritical, "Error"
        Exit Sub
    End If
   
    Dim oPart As PartDocument
    Set oPart = ThisApplication.ActiveDocument
   
    If Not TypeOf ThisApplication.ActiveEditObject Is Sketch Then
        MsgBox "No avtive sketch found", vbCritical, "Error"
        Exit Sub
    End If

    Dim oSketch As Inventor.Sketch
    Set oSketch = ThisApplication.ActiveEditObject
   
    On Error Resume Next
    oPart.SelectSet.Clear
    Dim oDimension As DimensionConstraint
    For Each oDimension In oSketch.DimensionConstraints
        oPart.SelectSet.Select oDimension
        oDimension.Delete
    Next
   
    If oPart.SelectSet.Count <> 0 Then
        MsgBox "It was not possible to delete selected dimensions.", vbCritical, "Error"
    End If
End Sub

---

------------------
Grüße Igor

FX64 Software Solutions - Inventor Tools
FX64 LambdaSpect - Lichtsimulation mit Autodesk Inventor

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Igor, du das werde ich mal testen und dann Bescheid geben, denn die nächste Skizze werde ich in ca. 2h kopieren. Aber damit spare ich Zeit  . herzlich Sascha

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

oh das geht sehr gut, danke dir sehr. herzliche Grüsse Sascha

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Sascha, und danke für die Rückmeldung!

------------------
Grüße Igor

FX64 Software Solutions - Inventor Tools
FX64 LambdaSpect - Lichtsimulation mit Autodesk Inventor

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ich bin mir nicht ganz sicher aber geht es nicht auch wenn man einfach alles markiert dann ENTF drück fragt er eh nach ob man die Ansicht X auch mitlöschen möchte drückt man nein verschwindet alles bis auf die Ansicht. Textfelder allerdings auch...

------------------
Grüße aus Wien
Philipp
http://black-evolution.de/

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo, es geht mir um die Maße in einer ipt in einer Skizze. herzlich Sascha

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von axi92:
... alles markiert ... verschwindet alles bis auf die Ansicht. Textfelder allerdings auch ...

---

In der Zeichnung kann man einen benutzerdefinierten Auswahlfilder verwenden, der nur Bemaßungen selektiert.

Nur gibt es den nicht in der Skizzenumgebung, sondern nur in der Zeichnungsumgebung, wie der Fragesteller schon im Eröffnungsbeitrag festgestellt hat.

------------------
Michael Puschner
Autodesk Inventor Certified Expert
Autodesk Inventor Certified Professional
Mensch und Maschine Scholle GmbH

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Guten Tag, ja ich krame hier wohl einen sehr alten Beitrag wieder ans Licht.

Das Makro hat einwandfrei innerhalb der Skizze einer *.ipt funktioniert.

Nun zu meiner Frage bzw. Bitte.

Wäre es möglich solch ein Makro auch innerhalb eines Blocks zu verwenden?
Da kommt leider immer eine Fehlermeldung : "Error , No avtive sketch found"

denke der Schreibfehler ist da jetzt mal zu ignorieren.
Wäre nur wirklich sehr schön wenn es auch im Block funktionieren würde.

Schon mal vielen Dank im Voraus ^^

freundliche Grüße
Dennis

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Ein Skizzenblock ist halt keine Skizze. Daher funktioniert der Code so nicht, war ja auch nicht gefordert. Es lässt sich aber relativ einfach erweitern:

Code:

---

Option Explicit

    ' Macro removes all dimensions from the active sketch or
    ' sketchblock
    ' Needs the active document and the sketch / sketchblock
    ' in edit mode
    ' original FX64 daywa1k3r, Igor Zupevc, 16.07.2014
    ' modified rkauskh, 02.05.2024
    Sub DeleteAllSketchDimensions()
        If ThisApplication.ActiveDocument Is Nothing Then
            MsgBox "No active document found", vbCritical, "Error"
            Exit Sub
        End If
      
        Dim oPart As PartDocument
        Set oPart = ThisApplication.ActiveDocument
      
        Dim oDimension As DimensionConstraint
       
        If TypeOf ThisApplication.ActiveEditObject Is Sketch Then
            Dim oSketch As Inventor.Sketch
            Set oSketch = ThisApplication.ActiveEditObject
                   
            oPart.SelectSet.Clear
           
            On Error Resume Next
            For Each oDimension In oSketch.DimensionConstraints
                oPart.SelectSet.Select oDimension
                oDimension.Delete
            Next
      
            If oPart.SelectSet.count <> 0 Then
            MsgBox "It was not possible to delete selected dimensions.", vbCritical, "Error"
            End If
        ElseIf TypeOf ThisApplication.ActiveEditObject Is SketchBlock Then
            Dim oSketchBlock As Inventor.SketchBlock
            Set oSketchBlock = ThisApplication.ActiveEditObject
           
            oPart.SelectSet.Clear
           
            On Error Resume Next
            For Each oDimension In oSketchBlock.Definition.DimensionConstraints
                oPart.SelectSet.Select oDimension
                oDimension.Delete
            Next
      
            If oPart.SelectSet.count <> 0 Then
            MsgBox "It was not possible to delete selected dimensions.", vbCritical, "Error"
            End If
        Else
            MsgBox "No active sketch or sketchblock found", vbCritical, "Error"
            Exit Sub
        End If
    End Sub

---

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi Dennis,

unten der etwas angepasste Code. Dieser hat in meinem minimal-Test funktioniert.

Ich habe auch einen Unterschied festgestellt, ob nun der Block
a) innerhalb einer Skizze, oder
b) aus dem Browserverzeichnis "Blöcke"
bearbeitet wird. Bei b) ging das Makro auch vorher schon.

Code:

---

Sub DeleteAllSketchDimensions()
    If ThisApplication.ActiveDocument Is Nothing Then
        MsgBox "No active document found", vbCritical, "Error"
        Exit Sub
    End If
 
    Dim oPart As PartDocument
    Set oPart = ThisApplication.ActiveDocument
 
    Dim oSketch As Inventor.Sketch
   
    If Not TypeOf ThisApplication.ActiveEditObject Is Sketch Then
        If TypeOf ThisApplication.ActiveEditObject Is SketchBlock Then
            Set oSketch = ThisApplication.ActiveEditObject.Definition
        Else
            MsgBox "No avtive sketch found", vbCritical, "Error"
            Exit Sub
        End If
    Else    'es handelt sich um eine Sketch (oder auch SketchBlockDefinition)
        Set oSketch = ThisApplication.ActiveEditObject
    End If
   
 
    On Error Resume Next
    oPart.SelectSet.Clear
    Dim oDimension As DimensionConstraint
    For Each oDimension In oSketch.DimensionConstraints
        oPart.SelectSet.Select oDimension
        oDimension.Delete
    Next
 
    If oPart.SelectSet.Count <> 0 Then
        MsgBox "It was not possible to delete selected dimensions.", vbCritical, "Error"
    End If
End Sub

---

------------------
Gruß KraBBy

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

OT
Hi Ralf, so kanns gehen. Zeitgleich gepostet ... 

------------------
Gruß KraBBy

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen herzlichen Dank. Ihr habt mir damit sehr geholfen.
Kenne mich in diesem Bereich einfach überhaupt nicht aus.

Immer wieder faszinierend was alles so möglich ist wenn man weiß wie ^^

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin!

Es ist vielleicht ein dumme Frage, aber: Wozu ist es gut, alle Maße in einer Skizze zu löschen? Das Bedürfnis habe ich noch nie gehabt.

------------------
Roland  
www.Das-Entwicklungsbuero.de

It's not the hammer - it's the way you hit!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Roland,

es gibt keine dummen Fragen ^^

um es möglichst kurz zu halten will ich es mal so sagen.
Wir arbeiten hier in 2,5 D um unsere Bauteile mit Hilfe von Drahterodiermaschinen nachzuarbeiten.
Da kommt es oftmals vor, dass sich die Bemaßungen und Abhängigkeiten erübrigen die man vor der letzten Änderung gesetzt hat.
Abhängigkeiten lassen sich ja auf einen Schlag löschen.
Nur eben keine Bemaßungen.

Mit dem Makro erspare ich mir einiges an Zeit und geklicke ^^

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP