---

Hallo Liebe NX VB.NET Gemeinde,

habe folgendes Problem selektiere eine Kante oder Kurve über eine Funktion und bekomme ein NXObject zurück.
Von diesem NXObject benötige ich den Durchmesser wie könnte ich diesen herausbekommen?

Code:

---

Public Function Select_Hole() As NXObject

Dim ui As UI = GetUI()
Dim message As String = "Bohrung wählen!"
Dim title As String = "Bohrung wählen!"

Dim scope As Selection.SelectionScope = Selection.SelectionScope.AnyInAssembly
Dim keepHighlighted As Boolean = True
Dim includeFeatures As Boolean = True

Dim selectionAction As Selection.SelectionAction = Selection.SelectionAction.ClearAndEnableSpecific

Dim selectionMask_array(1) As Selection.MaskTriple
With selectionMask_array(0)
            .Type = UFConstants.UF_solid_type
            .Subtype = UFConstants.UF_solid_edge_subtype
            .SolidBodySubtype = UFConstants.UF_solid_edge_subtype
End With
With selectionMask_array(1)
            .Type = UFConstants.UF_circle_type
            '.Subtype = UFConstants.UF_all_subtype
End With

Dim selectedObject As NXObject = Nothing

Dim cursor As Point3d

ui.SelectionManager.SelectObject(message, title, scope, _
                                        selectionAction, includeFeatures, _
                                        keepHighlighted, selectionMask_array, _
                                        selectedObject, cursor)

Dim Hole_Tag As NXObject = CType(selectedObject, NXObject)

Return Hole_Object

End Function

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo NXDJ,

von einem allgemeinen NXObject wirst Du keine typspezifischen Infos, wie z.B. Durchmesser abfragen können. Dazu muß es zunächst in den entprechenden Typ gewandelt werden, also einen Arc. Der Arc hat das Property Radius, das Du dann verwenden kannst.
Das könnte in etwa so aussehen:

dim my_arc as arc = ctype(nxobj, arc)
dim rad as double = my_arc.radius

Gruß, Michael

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

1: "Hole_Object" ist nicht bekannt und ausserdem ist "selectedObject" bereits vom Typ "NXObject".
2: das 1. Mask Triple sieht auch merkwürdig aus.
3: Eine Edge kann man nicht in einen Arc casten und führt zu einer Exception.

Es gibt einen Beispielcode report_circular_edge_info, das den UF_EVAL Wrapper nutzt.
Alles zusammengefasst würde dann ungefähr so aussehen:

Code:

---

Option Strict Off
Imports System
Imports NXOpen
Imports NXOpen.UI
Imports NXOpen.UF

Module report_radius_of_circle_or_circular_edge
Sub Main

Dim theSession As Session = Session.GetSession()
Dim theUI As UI = UI.GetUI()
Dim lw As ListingWindow = theSession.ListingWindow()
Dim obj As NXObject

While select_a_circular_object(obj) = Selection.Response.Ok
    Dim rad as double
    If obj.GetType().ToString() = "NXOpen.Arc" Then
        Dim my_arc as arc = ctype(obj, arc)
        rad = my_arc.radius
    Else
        rad = get_edge_radius(obj.Tag)
    End If
    lw.Open()
    lw.WriteLine("Radius: " + rad.ToString())
End While

End Sub

Function select_a_circular_object(ByRef obj As NXObject)

    Dim ui As UI = ui.GetUI()
    Dim message As String = "Select a circular object"
    Dim title As String = "Selection"
    Dim selectionMask(1) As Selection.MaskTriple
        With selectionMask(0)
            .Type = UFConstants.UF_solid_type
            .Subtype = UFConstants.UF_solid_edge_subtype
            .SolidBodySubtype = UFConstants.UF_UI_SEL_FEATURE_CIRCULAR_EDGE
        End With
        With selectionMask(1)
            .Type = UFConstants.UF_circle_type
            .Subtype = 0
            .SolidBodySubtype = 0
        End With
    Dim cursor As Point3d = Nothing

    Dim resp As Selection.Response = _
        ui.SelectionManager.SelectObject(message, title, _
            Selection.SelectionScope.WorkPart, _
            Selection.SelectionAction.ClearAndEnableSpecific, _
            False, False, selectionMask, obj, cursor)

    If resp = Selection.Response.ObjectSelected Or _
      resp = Selection.Response.ObjectSelectedByName Then
        return Selection.Response.Ok
    Else
        return Selection.Response.Cancel
    End If

End Function

Function get_edge_radius(ByVal edge_tag As Tag) As double
    Dim theUFSession As UFSession = UFSession.GetUFSession()
    Dim arc_evaluator As System.IntPtr
    Dim arc_data As NXOpen.UF.UFEval.Arc

    theUFSession.Eval.Initialize(edge_tag, arc_evaluator)
    theUFSession.Eval.AskArc(arc_evaluator, arc_data)
    theUFSession.UF.Free(arc_evaluator)

    Return arc_data.radius
End Function

End Module

---

[Diese Nachricht wurde von Overcast am 20. Jan. 2009 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke für die schnellen Antworten haben mir sehr weitergeholfen!!! 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP