---

Macro.txt

moin.

Ich habe ein kleines Problem.

Einzusetzende Symbole sind in einer externen Bibliotheksdatei (Bibliothek.idw) im Netzwerk abgelegt, um diese jedem zur Verfügung stellen zu können.
Nun kann es sein, dass sich beispielsweise Norm-Angaben verändern, und diese Texte (in den Symbolen) dann aktualisiert werden müssen.

Es besteht di Möglichkeit, dass man eine ältere Zeichnung aufruft, und sich dort ein solches Symbol befindet. - Diese möchte ich mit einem Macro tauschen (mit der aktuellsten Version, wenn vorhanden).

Ich kann die Position des Symbols ermitteln.
Ich kann dieses Symbol löschen.
Ich kann an der gleichen Stelle das Symbol neu einsetzten.

Hier wird jedoch immer das schon vorhandene (aber zuvor gelöschte) Symbol aus den Zeichnungsresourcen genutzt.

Wie kann ich meinem Macro klarmachen, dass er das (externe) Symbol aus der Bibliotheksdatei verwenden soll?

Für Lösungsansätzen wäre ich Euch dankbar.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus,

wenn der Name des Symbols gleich bleibt (genauer der Name der Definition) UND alle Exemplare des Symbols in der Zeichnung auf "aktuell" gestellt werden sollen, dann ist es relativ einfach möglich: Es reicht die Definition zu ersetzen.

Das klappt übrigens auch von Hand: Definition in den Zg.Ressourcen kopieren, auf dem Ordner Skizzensymbole der Ressourcen der Ziel-idw einfügen. Ist der Name schon da, wird gefragt ob überschrieben werden soll -> das ändert alle Exemplare.

Per Makro

Code:

---

Function SymbDef_aus_Template(oIDW As DrawingDocument, sSymbName As String) As SketchedSymbolDefinition
' fügt eine SketchedSymb.Definition in eine idw ein
' sollte gleichnamiges Symbol bereits vorh sein, wird überschrieben -> kann also ggf. auch zum Aktualsieren genutzt werden
'
' oIDW:        Zg.Document in das das Symbol eingefügt wird
' sSymbName:    Name des Symbols
'
' KraBBy 22.11.2018

    Const sIDW_Vorlage As String = "C:\...\Norm.idw"  '##### Anpassen! #####
                                                                                         
   
    'neue idw aus Vorlage öffnen
    Dim oVorlage As DrawingDocument
    Set oVorlage = ThisApplication.Documents.Add(kDrawingDocumentObject, sIDW_Vorlage, False) 'Visible = False
   
    'Symb.Def finden
    Dim oSkSymbDef As SketchedSymbolDefinition
    On Error Resume Next
    Set oSkSymbDef = oVorlage.SketchedSymbolDefinitions.Item(sSymbName)
   
    If 0 = Err.Number And Not oSkSymbDef Is Nothing Then
        'Symb gefunden
        On Error GoTo 0
        'kopieren
        Set SymbDef_aus_Template = oSkSymbDef.CopyTo(oIDW, True)    'Rückgabewert
            'dabei ReplaceExisting = True
    Else
        'Symbol mit dem Namen nicht vorhanden
        On Error GoTo 0
        Set SymbDef_aus_Template = Nothing      'Rückgabewert
    End If
   
    'Vorlage schließen
    oVorlage.Close (True)
   
End Function

---

------------------
Gruß KraBBy

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Besten Dank, KraBBy!

Nach entsprechenden Anpassungen an meine Gegebenheiten, läuft das Makro so, wie ich es mir erhofft hatte.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP