---

Hallo,

gibt es eine Moeglichkeit Daten aus mehreren Tabellen in verschiedenen Exceldateien in eine Tabelle in einer Datei zusammenzufuegen.

Hintergrund: wir erstellen Teileangebote per Excel die dann in einzelne Dateien abgespeichert werden.
Ich will nun eine Datei erstellen, in die die Zeilen der kalkulierten Teile aus den verschiedenen Angebotsdateien sammelt.
Die Kalkulations haben eine meist Konstante Startzeile aber dann verschiedene Anzahl von Zeilen.

hat irgendwer schon mal ein so aehnliches Macro geschrieben und kann es mir zur verfuehgung stellen, so das ich bei null anfangen muss.

danke schon mal im voraus

Gruss
Ray

------------------
Barbarus hic ego sum, quia non intellegor ulli!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

ungetestet:

Code:

---

Sub MehrereOeffnen()
    Dim strVerzeichnis As String
    Dim strTyp As String
    Dim strDateiname As String
    Dim lngLetzteQuelle As Long
    Dim lngLetzteZiel As Long
    strTyp = "*.xlsx*"  '<== Dateityp anpassen
    strVerzeichnis = "D:\Dateien\"  '<== Verzeichnis anpassen
    Application.ScreenUpdating = False
    strDateiname = Dir(strVerzeichnis & strTyp)
    With ThisWorkbook.Worksheets("Ziel")
        Do While strDateiname <> ""
            Workbooks.Open Filename:=strVerzeichnis & strDateiname
            ' letzte belegte Zeile in Quelltabelle
            lngLetzteQuelle = ActiveWorkbook.Worksheets("Quelle").Cells.Find(What:="*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
            ' letzte belegte Zeile in Zieltabelle
            lngLetzteZiel = .Cells.Find(What:="*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
            ' Bereich A3:Z+letzte belegte Zeile kopieren  <== Spalten und Startzeile anpassen
            ActiveWorkbook.Worksheets("Quelle").Range("A3:Z" & lngLetzteQuelle).Copy .Cells(lngLetzteZiel + 1, 1)
            ActiveWorkbook.Close True
            strDateiname = Dir
        Loop
    End With
    Application.ScreenUpdating = True
End Sub

---

Alle zu kopierenden Dateien müssen im selben Verzeichnis liegen.

Namen für Zieltabelle und Quelltabelle ebenfalls anpassen!

------------------
Bis später,
Karin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP