Hot News:

Mit Unterstützung durch:

  Foren auf CAD.de (alle Foren)
  SolidWorks
  Benutzerdefinierte Eigenschaften per Makro suchen und ersetzen

Antwort erstellen  Neues Thema erstellen
CAD.de Login | Logout | Profil | Profil bearbeiten | Registrieren | Voreinstellungen | Hilfe | Suchen

Anzeige:

Darstellung des Themas zum Ausdrucken. Bitte dann die Druckfunktion des Browsers verwenden. | Suche nach Beiträgen nächster neuer Beitrag | nächster älterer Beitrag
  
Gut zu wissen: Hilfreiche Tipps und Tricks aus der Praxis prägnant, und auf den Punkt gebracht für SOLIDWORKS
  
SolidCAM bei der 23. Hausmesse des Technikszentrums by Werkzeug-Eylert
Autor Thema:  Benutzerdefinierte Eigenschaften per Makro suchen und ersetzen (850 mal gelesen)
Andreoid
Mitglied
B. Eng. Konstruktion


Sehen Sie sich das Profil von Andreoid an!   Senden Sie eine Private Message an Andreoid  Schreiben Sie einen Gästebucheintrag für Andreoid

Beiträge: 25
Registriert: 21.11.2010

erstellt am: 09. Mai. 2022 16:08    Editieren oder löschen Sie diesen Beitrag!  <-- editieren / zitieren -->   Antwort mit Zitat in Fett Antwort mit kursivem Zitat    Unities abgeben: 1 Unity (wenig hilfreich, aber dennoch)2 Unities3 Unities4 Unities5 Unities6 Unities7 Unities8 Unities9 Unities10 Unities

Hallo Zusammen,

ich suche eine Möglichkeit bei Benutzerdefinierten Eigenschaften die Variablennamen gezielt zu suchen und zu ersetzen.
Beispiel: aus der Eigenschaft (ALT_Gewicht; 10kg)  soll die Eigenschaft (NEU_Gewicht; 10kg) werden.


Hintergrund: Ich selber habe keinerlei VB Erfahrung und habe am Wochenende versucht mit einem Kumpel, mit Google und dem Forum als Hilfe, das Programm logisch zu zerlegen und zurechtzubasteln. Nach stundenlangen Trial&Error dann mit rauchenden Köpfen und mäßigem Erfolg geendet:
Wir konnte ein Löschmakro so umschreiben, dass dieses in den Benutzerdefinierten Eingeschaften die Variablennamen nach einander ausliest, die ersten 4 Buchstaben ersetz, und diese neu als Zeile anlegt:

Code:

    InfoCount = Part.GetCustomInfoCount2("")            ' wieviele Benutzerdef. Eigenschaften im akt. Teil?
    InfoNames = Part.GetCustomInfoNames2("")            ' Alle Namen der Benutzerdef. Eigenschaften in ein Variant einlesen
    InfoValue = Part.GetCustomInfoValue("", "")        ' Alle Werte der Benutzerdef. Eigenschaften in ein Variant einlesen

        For K = 0 To InfoCount - 1                      ' Schleife durch alle Benutzerdef. Eigenschaften
                If Left(InfoNames(K), 4) <> "NEU_" Then ' Or Left(InfoNames(K),1) = "NEU_" Then
                    'MsgBox Value
                    'Debug.Print Value
                    'Value = InfoValue(K)
                    'MsgBox Value
                    'Debug.Print Value
                    test_1 = Left(InfoNames(K), 40)
                    'MsgBox test_1
                    'Debug.Print test_1
                    test = Replace(test_1, "ALT_", "NEU_")
                    'MsgBox test
                    'Debug.Print test
                    Retval = Part.AddCustomInfo2(test, swCustomInfoText, Value) 'AddCustomInfo2(FieldName As String, FieldType As Long, FieldValue As String) As Boolean
                End If
        Next K



oben die alten Zeilen mit Variablennamen und den zugehörigen Werten
unten die neuen Zeilen mit Variablennamen OHNE Werte

das wäre soweit ja in Ordnung, wenn ich nur einen Befehl hätte der auch den Wert zu dem Variablennamen überträgt.

Value = InfoValue(K) hat leider nicht geklappt

    Ähnlich Themen wie z.B.
    Benutzerdefinierte Eigenschaften per Makro/Textbox ändern  https://ww3.cad.de/foren/ubb/Forum2/HTML/021862.shtml
    haben mir nicht weiterhefen können. Hier wird z.B. der Wert abgefragt, mit einer vorgegebenen Varibalen eingetragen. Ich brauche jedoch etwas was den Wert vorher ausliest.
    Das Eintragen hatte testweise mit value = "3" ;    Retval = Part.AddCustomInfo2(test, swCustomInfoText, Value)  bereits funktioniert. Wobei ich nicht weis, ob das auch für die Konfigurationen gilt.

Das Rauslöschen der überigen Zeilen mit "nicht NEU_" klappt über die Vorlage des oben angesprochenen Löschmmakros. Das Makro ist auch in dem Beipsielprogramm im Anhang enthalten, jedoch auskommentiert.
https://ww3.cad.de/foren/ubb/upl/A/Andreoid/Eigenschaftensuchenundersetzen.zip

Weiterhin klappt das Löschmakro in den konfigurationsspezifischen Eigenschaften wunderbar... aber nicht meine "suchen_und_ersetzen"makro


Code:

         
    numConfigs = Part.GetConfigurationCount()
    Names = Part.GetConfigurationNames()
   
         
        For i = 0 To numConfigs - 1                    ' Schleife Durch alle Konfigurationen
                                                           
                                                              ' Konfigurationsspezifischen fieldNames auslesen
            InfoCount = Part.GetCustomInfoCount2(Names(i))    ' wieviele konf. Eigenschaften in der akt. Konfiguration?
            InfoNames = Part.GetCustomInfoNames2(Names(i))    ' Alle Namen der Konf. Eigenschaften in ein Variant einlesen
   
       
            For K = 0 To InfoCount - 1                                      ' Schleife durch alle konf. Eigenschaften
                If Left(InfoNames(K), 4) <> "NEU_" Then
                    test_1 = Left(InfoNames(K), 40)
                    test = Replace(test_1, "ALT_", "NEU_")
                    Retval = Part.AddCustomInfo2(test, swCustomInfoText, Value)
                End If
            Next K
           
        Next i
   
End If
Set Part = Nothing
Set swApp = Nothing


End Sub


das macht nei denm Konfiguratioenn leider garnichts.

Kann mir da Jemand helfen das grade zu ziehen? Oder wäre es gar einfacher die Vorlage aus dem anderen Thread zu modifizieren? https://ww3.cad.de/foren/ubb/Forum2/HTML/021862.shtml#000011

Grüße aus Köln
André

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

Ralf Tide
Moderator
-




Sehen Sie sich das Profil von Ralf Tide an!   Senden Sie eine Private Message an Ralf Tide  Schreiben Sie einen Gästebucheintrag für Ralf Tide

Beiträge: 4978
Registriert: 06.08.2001

Sehr seltsame Dinge passiern <Klaus Lage - Toy Story>
.-)

erstellt am: 10. Mai. 2022 06:37    Editieren oder löschen Sie diesen Beitrag!  <-- editieren / zitieren -->   Antwort mit Zitat in Fett Antwort mit kursivem Zitat    Unities abgeben: 1 Unity (wenig hilfreich, aber dennoch)2 Unities3 Unities4 Unities5 Unities6 Unities7 Unities8 Unities9 Unities10 Unities Nur für Andreoid 10 Unities + Antwort hilfreich

Hallo André,

vielleicht hilft Dir auch http://solidworks.cad.de/mm_35.htm

Da kannst Du sehen wie der Zugriff auf die konfigurationsspezifischen Dateieigenschaften funktioniert. Analog hast Du es mit den benutzerdefinierten Dateieigenschaften schon geschafft 

HTH
Ralf

------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

Andreoid
Mitglied
B. Eng. Konstruktion


Sehen Sie sich das Profil von Andreoid an!   Senden Sie eine Private Message an Andreoid  Schreiben Sie einen Gästebucheintrag für Andreoid

Beiträge: 25
Registriert: 21.11.2010

erstellt am: 10. Mai. 2022 09:20    Editieren oder löschen Sie diesen Beitrag!  <-- editieren / zitieren -->   Antwort mit Zitat in Fett Antwort mit kursivem Zitat    Unities abgeben: 1 Unity (wenig hilfreich, aber dennoch)2 Unities3 Unities4 Unities5 Unities6 Unities7 Unities8 Unities9 Unities10 Unities

Code:

    For Each Config In PropConfigs
        For Each Prop In PropNames
            ' als Dateieigenschaft wieder einsetzen, Dummywert "bitte ausfüllen" eintragen
            ' und neu hinzufügen; falls schon vorhanden passiert nix
            Debug.Print ModelDoc.AddCustomInfo3(Config, Prop, swCustomInfoText, "bitte ausfüllen")
        Next
    Next

danke für den Tipp. Die Bearbeitung der Kofigurationen (mit "For Each Config....") sieht einfacher und schicker aus als bei meiner Schleife.
Da ich jedoch nicht einfach nur in jede Konfiguration etwas reinpfeffern muss, sondern auch Zeile für Zeile auslesen muss, komme ich aber wohl um die Schleifen nicht drum herum.

die AddCustomInfo3 könnte ich für die Konfigurationen dann wohl wie folgt reinbastelen

Code:

   For Each Config In PropConfigs


Retval = Part.AddCustomInfo3 (

    numConfigs = Part.GetConfigurationCount()
    Names = Part.GetConfigurationNames()
  
        
        For i = 0 To numConfigs - 1                    ' Schleife Durch alle Konfigurationen
                                                          
                                                              ' Konfigurationsspezifischen fieldNames auslesen
            InfoCount = Part.GetCustomInfoCount2(Names(i))    ' wieviele konf. Eigenschaften in der akt. Konfiguration?
            InfoNames = Part.GetCustomInfoNames2(Names(i))    ' Alle Namen der Konf. Eigenschaften in ein Variant einlesen
  
      
            For K = 0 To InfoCount - 1                                      ' Schleife durch alle konf. Eigenschaften
                If Left(InfoNames(K), 4) <> "NEU_" Then
                    test_1 = Left(InfoNames(K), 40)
                    test = Replace(test_1, "ALT_", "NEU_")
                    Retval = Part.AddCustomInfo3(Names, test, swCustomInfoText, Value)
                End If
            Next K
          
        Next i
  
End If
Set Part = Nothing
Set swApp = Nothing

End Sub


werde das mal testen

edit:
----------------------------------------------
bekomem in der Zeile leider einen Laufzeitfehler '13': Typen unverträglich

[Diese Nachricht wurde von Andreoid am 10. Mai. 2022 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

bk.sc
Ehrenmitglied V.I.P. h.c.
Konstrukteur Sondermaschinenbau



Sehen Sie sich das Profil von bk.sc an!   Senden Sie eine Private Message an bk.sc  Schreiben Sie einen Gästebucheintrag für bk.sc

Beiträge: 2776
Registriert: 18.07.2012

-Solid Works 2019 SP5
-Pro Engineer WF 3

erstellt am: 10. Mai. 2022 09:27    Editieren oder löschen Sie diesen Beitrag!  <-- editieren / zitieren -->   Antwort mit Zitat in Fett Antwort mit kursivem Zitat    Unities abgeben: 1 Unity (wenig hilfreich, aber dennoch)2 Unities3 Unities4 Unities5 Unities6 Unities7 Unities8 Unities9 Unities10 Unities Nur für Andreoid 10 Unities + Antwort hilfreich

Hallo André,

ich würde dir das arbeiten mit dem "ICustomPropertyManager Interface" empfehlen, da wird der ganze Code schmaller.

Mal auf die schnelle zusammenkopiert (alle Eigenschaften mit "ALT_" werden mit "NEU_" neu erstellt und die "ALT_" Eigenschaft gelöscht, Eigenschaften ohne "ALT_" werden ignoriert, beachte es wird der nicht evaluierte Wert übertragen (daher das Get3) falls Verknüpfungen zu Masse, Bemaßungen etc. vorhanden sind.

Code:
Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModel As ModelDoc2
Dim swModelDocExt As ModelDocExtension
Dim swCustPropMgr As CustomPropertyManager

Dim varKonfigNames As Variant

Dim varCustomPropNames As Variant

Dim varCustomPropTypes As Variant
Dim varCustomPropValues As Variant
Dim varCustomPropResolved As Variant
Dim varCustomPropLinked As Variant

Dim strCustomPropValue As String
Dim strCustomPropResValue As String

Dim strCustomPropNewName As String

Dim boolstatus As Boolean
Dim lWarnings As Long
Dim i As Integer
Dim j As Integer

Sub main()

Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swModelDocExt = swModel.Extension

varKonfigNames = swModel.GetConfigurationNames

ReDim Preserve varKonfigNames(UBound(varKonfigNames) + 1)

For j = 0 To UBound(varKonfigNames)

    Set swCustPropMgr = swModelDocExt.CustomPropertyManager(varKonfigNames(j))

    lWarnings = swCustPropMgr.GetAll3(varCustomPropNames, varCustomPropTypes, varCustomPropValues, varCustomPropResolved, varCustomPropLinked)

    For i = 0 To UBound(varCustomPropNames)
   
        boolstatus = swCustPropMgr.Get3(varCustomPropNames(i), True, strCustomPropValue, strCustomPropResValue)
   
        If InStr(1, varCustomPropNames(i), "ALT_", vbTextCompare) > 0 Then
   
            strCustomPropNewName = Replace(varCustomPropNames(i), "ALT_", "NEU_")
            lWarnings = swCustPropMgr.Add3(strCustomPropNewName, varCustomPropTypes(i), strCustomPropValue, swCustomPropertyOnlyIfNew)
            lWarnings = swCustPropMgr.Delete2(varCustomPropNames(i))
       
        End If

    Next i

Next j

swModel.SetSaveFlag

End Sub


Gruß
Bernd

EDIT: Hab die Konfigurationsspezifischen Eigenschaften ergänzt, das hatte ich überlesen. 

------------------
--- Man muß nicht alles wissen, man muß nur wissen wo es steht ---

Staatlich anerkannte Deutschniete  

[Diese Nachricht wurde von bk.sc am 10. Mai. 2022 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

Andreoid
Mitglied
B. Eng. Konstruktion


Sehen Sie sich das Profil von Andreoid an!   Senden Sie eine Private Message an Andreoid  Schreiben Sie einen Gästebucheintrag für Andreoid

Beiträge: 25
Registriert: 21.11.2010

erstellt am: 11. Mai. 2022 12:12    Editieren oder löschen Sie diesen Beitrag!  <-- editieren / zitieren -->   Antwort mit Zitat in Fett Antwort mit kursivem Zitat    Unities abgeben: 1 Unity (wenig hilfreich, aber dennoch)2 Unities3 Unities4 Unities5 Unities6 Unities7 Unities8 Unities9 Unities10 Unities

Vielen vielen lieben Dank Bernd! 

habe das mal bei mir in den Code reingebastelt. Jetzt funktioniert alles komplett wie es soll.

Hier für alle anderen, die auch nach so etwas suchen, der komplette Code mit "suchen und ersetzen" und "alles andere rauslöschen". Zusätzlich werden den 4 Variablen die SW-Werte (Masse. Volumen, Dichte, Material) zugewiesen und nachgetragen.
Ist jetzt nicht so schön kurz wie vom Bernd, aber es macht was es soll.

Code:

Dim swApp As SldWorks.SldWorks
Dim swModel As ModelDoc2
Dim swModelDocExt As ModelDocExtension
Dim swCustPropMgr As CustomPropertyManager


Dim Part As Object
Dim InfoCount As Long
Dim InfoNames As Variant
Dim InfoValue As Variant
Dim DelName As String
Dim Conf As Object
Dim ConfName As String
Dim ConfEinlesen As Long
Dim FirstConfName As String
Dim test As String
Dim test_1 As String
Dim Value As String
Dim Value_var As String
Dim K As Integer

Dim varKonfigNames As Variant

Dim varCustomPropNames As Variant

Dim varCustomPropTypes As Variant
Dim varCustomPropValues As Variant
Dim varCustomPropResolved As Variant
Dim varCustomPropLinked As Variant

Dim strCustomPropValue As String
Dim strCustomPropResValue As String

Dim strCustomPropNewName As String

Dim boolstatus As Boolean
Dim lWarnings As Long
Dim i As Integer
Dim j As Integer
Dim iCounter As Integer


Sub main()
    Set swApp = Application.SldWorks
    Set Part = swApp.ActiveDoc
    Dim fileext    As Integer
    Dim p_data(4, 2) As Variant

    ' Hier werden die Solidworkssystem Variablen bestimmt
    p_data(1, 1) = "NEU_Werkstoff"
    p_data(1, 2) = "SW-Material"
    p_data(2, 1) = "NEU_Gewicht"
    p_data(2, 2) = "SW-Mass"
    p_data(3, 1) = "NEU_Volumen"
    p_data(3, 2) = "SW-Volume"
    p_data(4, 1) = "NEU_Dichte"
    p_data(4, 2) = "SW-Density"
   
    If MsgBox("Sind alle Komponenten ausgecheckt?", vbYesNo, "Hinweis") = vbNo Then
      Exit Sub
    Else
   
    If Part Is Nothing Then
        MsgBox "Keine Datei vorhanden", vbCritical, "Makro - Dateieigenschaften löschen"
      Else
        'Dateiendung ermitteln
          fileext = Extension2Type(Part.GetPathName)
       
          If fileext = 0 Then
                MsgBox "Die SOLIDWOKS-Datei ist noch nicht gespeichert", vbExclamation, "Makro - Dateieigenschaften löschen"
          Else
                suchen_und_ersetzen
                deleteprozess swApp, Part, p_data
                AddCustPrps swApp, Part, p_data
                Debug.Print "Assembly, Part and Drawing"
          End If
        End If
    End If
    MsgBox "Alle NICHT - NEU_ Eigenschaften sind gelöscht" & vbCrLf & "" & vbCrLf & "NEU_Dichte" & vbCrLf & "NEU_Gewicht" & vbCrLf & "NEU_Werkstoff" & vbCrLf & "NEU_Volumen            sind nachgetragen"
End Sub

Sub suchen_und_ersetzen()

Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swModelDocExt = swModel.Extension

varKonfigNames = swModel.GetConfigurationNames

ReDim Preserve varKonfigNames(UBound(varKonfigNames) + 1)

For j = 0 To UBound(varKonfigNames)

    Set swCustPropMgr = swModelDocExt.CustomPropertyManager(varKonfigNames(j))

    lWarnings = swCustPropMgr.GetAll3(varCustomPropNames, varCustomPropTypes, varCustomPropValues, varCustomPropResolved, varCustomPropLinked)

    For i = 0 To UBound(varCustomPropNames)
 
        boolstatus = swCustPropMgr.Get3(varCustomPropNames(i), True, strCustomPropValue, strCustomPropResValue)
 
        If InStr(1, varCustomPropNames(i), "ALT_", vbTextCompare) > 0 Then
 
            strCustomPropNewName = Replace(varCustomPropNames(i), "ALT_", "NEU_")
            lWarnings = swCustPropMgr.Add3(strCustomPropNewName, varCustomPropTypes(i), strCustomPropValue, swCustomPropertyOnlyIfNew)
            lWarnings = swCustPropMgr.Delete2(varCustomPropNames(i))
     
        End If

    Next i

Next j

swModel.SetSaveFlag

End Sub

'entfernt ALLE NICHT mit "NEU_" beginnenden Benutzereigenschaften
Sub deleteprozess(swApp As SldWorks.SldWorks, swModel As SldWorks.ModelDoc2, p_data As Variant)

Set swApp = GetObject(, "SldWorks.Application")
Set Part = swApp.ActiveDoc

If Not Part Is Nothing Then
    InfoCount = Part.GetCustomInfoCount2("")            ' wieviele Benutzerdef. Eigenschaften im akt. Teil?
    InfoNames = Part.GetCustomInfoNames2("")            ' Alle Namen der Benutzerdef. Eigenschaften in ein Variant einlesen
       
        For K = 0 To InfoCount - 1                      ' Schleife durch alle Benutzerdef. Eigenschaften
                If Left(InfoNames(K), 4) <> "NEU_" Then ' Or Left(InfoNames(K),1) = "NEU_" Then
                    Retval = Part.DeleteCustomInfo2("", InfoNames(K))    ' Löschen aller Eigenschaften
                End If
        Next K
         
    numConfigs = Part.GetConfigurationCount()
    Names = Part.GetConfigurationNames()
   
         
        For i = 0 To numConfigs - 1                    ' Schleife Durch alle Konfigurationen
                                                           
                                                              ' Konfigurationsspezifischen fieldNames auslesen
            InfoCount = Part.GetCustomInfoCount2(Names(i))    ' wieviele konf. Eigenschaften in der akt. Konfiguration?
            InfoNames = Part.GetCustomInfoNames2(Names(i))    ' Alle Namen der Konf. Eigenschaften in ein Variant einlesen
   
       
            For K = 0 To InfoCount - 1                                      ' Schleife durch alle konf. Eigenschaften
                If Left(InfoNames(K), 4) <> "NEU_" Then
                    Retval = Part.DeleteCustomInfo2(Names(i), InfoNames(K))  ' Löschen aller Eigenschaften
                End If
            Next K
           
        Next i
   

End If
Set Part = Nothing
Set swApp = Nothing


End Sub

'Setze Dateieigenschaften Masse, Volumen, Material fuer SLDASM, SLDPRT and SLDDRW
Sub AddCustPrps(swApp As SldWorks.SldWorks, swModel As SldWorks.ModelDoc2, p_data As Variant)

    Dim swCustPropMgr As SldWorks.CustomPropertyManager
    Dim vConfs As Variant
    Dim i As Integer
    Dim sFullpath As String
    Dim sFilename As String

  'Dateipfad ermitteln
    sFullpath = swModel.GetPathName
    'Dateiname
    sFilename = Mid(sFullpath, InStrRev(sFullpath, "\") + 1, Len(sFullpath))
   
    'Get all custom properties; Date added is the last one in the list
    Dim vNameArr            As Variant
    Dim vName              As Variant
   
          'Default-Config
            Set swCustPropMgr = swModel.Extension.CustomPropertyManager("")
           
             
            For iCounter = 1 To UBound(p_data)
                    Debug.Print (p_data(iCounter, 1) & " " & p_data(iCounter, 2))
                    swCustPropMgr.Add2 p_data(iCounter, 1), swCustomInfoText, """" & p_data(iCounter, 2) & "@" & sFilename & """"
            Next iCounter
           
            vConfs = swModel.GetConfigurationNames
       
            'All Configs
            For i = 0 To UBound(vConfs)
                Set swCustPropMgr = swModel.Extension.CustomPropertyManager(vConfs(i))
               
               
                For iCounter = 1 To UBound(p_data)
                    Debug.Print (p_data(iCounter, 1) & " " & p_data(iCounter, 2))
                    swCustPropMgr.Add2 p_data(iCounter, 1), swCustomInfoText, """" & p_data(iCounter, 2) & "@@" & vConfs(i) & "@" & sFilename & """"
                Next iCounter

            Next
   
End Sub

'Dateityp ermitteln
Function Extension2Type(ByVal strFileName As String) As swDocumentTypes_e

        Dim strExtension As String

        Extension2Type = swDocumentTypes_e.swDocNONE
        strExtension = Right(strFileName, Len(strFileName) - InStrRev(strFileName, "."))
        strExtension = LCase(strExtension)

        Select Case (strExtension)

            Case "sldprt"

                Extension2Type = swDocumentTypes_e.swDocPART

            Case "sldasm"

                Extension2Type = swDocumentTypes_e.swDocASSEMBLY

            Case "slddrw"

                Extension2Type = swDocumentTypes_e.swDocDRAWING
               
        End Select

    End Function



Kann man das Ganze noch ergänzen, dass es auch bei Baugruppen auf die Einzelteile anwendbar ist?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

bk.sc
Ehrenmitglied V.I.P. h.c.
Konstrukteur Sondermaschinenbau



Sehen Sie sich das Profil von bk.sc an!   Senden Sie eine Private Message an bk.sc  Schreiben Sie einen Gästebucheintrag für bk.sc

Beiträge: 2776
Registriert: 18.07.2012

-Solid Works 2019 SP5
-Pro Engineer WF 3

erstellt am: 12. Mai. 2022 12:27    Editieren oder löschen Sie diesen Beitrag!  <-- editieren / zitieren -->   Antwort mit Zitat in Fett Antwort mit kursivem Zitat    Unities abgeben: 1 Unity (wenig hilfreich, aber dennoch)2 Unities3 Unities4 Unities5 Unities6 Unities7 Unities8 Unities9 Unities10 Unities Nur für Andreoid 10 Unities + Antwort hilfreich


Props_Search-Replace.zip

 
Hallo,

anbei hab ich mal das Macro etwas nach meinem geschmack angepasst und um die Baugruppenstruktur ergänzt.

Beachte wenn in der Hauptbaugruppe Komponenten / Unterbaugruppen in allen Konfigurationen unterdrückt sind werden diese Ignoriert, das gilt auch für Komponenten / Unterunterbaugruppen in Unterbaugruppen die in der verwendeten Konfiguration unterdrückt sind (Quasi werden bei Baugruppen tieferer Ebenen nur die Komponenten / Baugruppen die in der verwendeten Konfiguration nicht unterdrückt sind beachtet).

Wenn du das aber dringend brauchst müsstest du unterdrückte Komponenten und Untergaugruppen (und unterdrückte Komponenten in Unterbaugruppen) z.B. öffnen, dafür würde dann aber das aktivieren aller Konfigurationen der Hauptbaugruppe natürlich entfallen.

Gruß
Bernd

------------------
--- Man muß nicht alles wissen, man muß nur wissen wo es steht ---

Staatlich anerkannte Deutschniete 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

Anzeige.:

Anzeige: (Infos zum Werbeplatz >>)

Darstellung des Themas zum Ausdrucken. Bitte dann die Druckfunktion des Browsers verwenden. | Suche nach Beiträgen

nächster neuerer Beitrag | nächster älterer Beitrag
Antwort erstellen


Diesen Beitrag mit Lesezeichen versehen ... | Nach anderen Beiträgen suchen | CAD.de-Newsletter

Administrative Optionen: Beitrag schliessen | Archivieren/Bewegen | Beitrag melden!

Fragen und Anregungen: Kritik-Forum | Neues aus der Community: Community-Forum

(c)2024 CAD.de | Impressum | Datenschutz