---

Hallo Forum,

ich hätte hier ein Problem/Frage und hoffe Ihr könnt mir weiterhelfen.
Zuvor habe ich schon hier nach Antworten gesucht aber irgendwie nicht wirklich was finden können.
Leider bin ich mit VBA nur bedingt vertraut, und in der SW-Umgebung hört es relativ schnell bei mir auf  .

Folgende Situation:
Ich habe ein Makro (siehe weiter unten) mit dem ich eine zuvor mit MacroSheet konfigurierte Baugruppe als eDrawings in ein fest definiertes Verzeichnis speichere. Das funktioniert auch wie gewollt.
Nun ist es so das nicht benötigte Teile/Unterbaugruppen beim konfigurieren vom MacroSheet unterdrückt werden.
Was ich jetzt gerne noch in meinem Makro reinbringen will ist:
Nach dem speichern als eDrawings soll bei allen unterdrückten Teile/Unterbaugruppen (aber nur auf oberster Ebene) die unterdrückung wieder aufgehoben werden.
Ich würde mich freuen wenn hier einer von Euch eine Lösung hätte, denn ich stoße hier an meine Grenzen.

Danke schon mal für Eure Rückmeldungen,
Gruß Lubber

Hier noch der aktuelle Code wie oben beschrieben:
Option Explicit

Dim swapp As Object
'Dim Part As Object
'Dim boolstatus As Boolean

Sub main()

Dim swapp As SldWorks.SldWorks
Dim swmodel As ModelDoc2
Dim FileName As String
Dim longStatus As Long

Const mainPath As String = "C:\SolidWorks Zeichnungen\eDrawings\"

Set swapp = Application.SldWorks
Set swmodel = swapp.ActiveDoc

FileName = InputBox("Dateiname eingeben", "speichern unter C:\SolidWorks Zeichnungen\eDrawings\", "")
Debug.Print mainPath & FileName & ".easm"
longStatus = swmodel.SaveAs3(mainPath & FileName & ".easm", 0, 0)
Debug.Print longStatus

    If longStatus <> 0 Then
        MsgBox "Speichern fehlgeschlagen, Artikelbezeichnung/Dateiname muss eingetragen werden"
    End If

'boolstatus = Part.Extension.SelectByID2("", "COMPONENT", 0, 0, 0, True, 0, Nothing, 0)

End Sub

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Lubber

Ich hab dir einmal den Code von hier -> Set All Assembly Components Lightweight or Resolved Example (VBA) in dein Makro implementiert.

Code:

---

Option Explicit

Sub main()
   
    Dim swapp As SldWorks.SldWorks
    Dim swmodel As ModelDoc2
    Dim FileName As String
    Dim longStatus As Long
   
    Const mainPath As String = "C:\SolidWorks Zeichnungen\eDrawings\"
   
    Set swapp = Application.SldWorks
    Set swmodel = swapp.ActiveDoc
   
    FileName = InputBox("Dateiname eingeben", "speichern unter C:\SolidWorks Zeichnungen\eDrawings\", "")
    Debug.Print mainPath & FileName & ".easm"
    longStatus = swmodel.SaveAs3(mainPath & FileName & ".easm", 0, 0)
    Debug.Print longStatus
   
    If longStatus <> 0 Then
        MsgBox "Speichern fehlgeschlagen, Artikelbezeichnung/Dateiname muss eingetragen werden"
    Else
        If swmodel.GetType = swDocASSEMBLY Then
            Dim swFeatMgr As SldWorks.FeatureManager
            Dim swConfigMgr As SldWorks.ConfigurationManager
            Dim swConfig As SldWorks.Configuration
            Dim swRootComp As SldWorks.Component2
           
            Set swFeatMgr = swmodel.FeatureManager
            Set swConfigMgr = swmodel.ConfigurationManager
            Set swConfig = swConfigMgr.ActiveConfiguration
            Set swRootComp = swConfig.GetRootComponent3(True)
            swFeatMgr.EnableFeatureTree = False
           
            Dim vChildCompArr As Variant
            Dim vChildComp As Variant
            Dim swChildComp As SldWorks.Component2
            Dim nRetVal As Long
           
            vChildCompArr = swRootComp.GetChildren
            For Each vChildComp In vChildCompArr
                Set swChildComp = vChildComp
                nRetVal = swChildComp.SetSuppression2(swComponentFullyResolved)
                Debug.Print swChildComp.Name2 & " <" & swChildComp.ReferencedConfiguration & "> --> " & swChildComp.GetPathName
            Next vChildComp
           
            swFeatMgr.EnableFeatureTree = True
        End If
    End If
   
End Sub

---

Gruss Andreas

------------------
21 ist nur die halbe Antwort.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Guten Morgen Andreas,

vielen Dank für die antwort und der Hilfe. Funktioniert hervorragend.
Was auch Top ist: Unterdrückte Teile in Unterbaugruppen bleiben verschont. Perfekt.
Ich habe ewig in der API-Hilfe gesucht, das aber nicht finden können.

Also, nochmals vielen Dank für die Hilfe und ein schönes Wochenende!

Gruß
Daniel

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP