---

Bild.jpg Bild2.jpg

Hallo Zusammen   

Ich möchte mit Hilfe des Taskplaners in ca. 500 Dateien (zum Teil mit mehreren vorhandenen Konfigurationen), konfigurationsspezifische Dateiinformationen erstellen (Bild2).
Das Problem ist das ich im Taskplaner in dem Feld "Konfiguration" (Bild, derzeit "Standard") den direkten Konfiguration-Namen eintragen muss.

Was muss ich im Feld "Konfiguration" eintragen damit es für Dateien mit mehreren Konfigurationen klappt?

Vielen Dank für eure Hilfe!   

Viele Grüße Daniel

[Diese Nachricht wurde von Cooper1988 am 03. Aug. 2020 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Mit dem Taskplaner kannst Du benutzerdefinierte Eigenschaften reinfahren. Konfigurationsspezifische Eigenschaften denke ich eher nicht ... da musst Du wohl was programmieren ...
Probier mal das Makro von der SolidWorks MakroMania - Tauschbörse

http://solidworks.cad.de/cgi-bin/topdl/download.pl?file=mmtb_08.zip

------------------
Grüße von der Saar
Uwe Blum

www.hydac.com/

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Uwe ,

schade, ich hatte gehofft das man im Taskplaner in dem Feld "Konfiguration" eine Art Platzhalter/Variable einträgt damit er die Eigenschaften für jede Konfiguration erstellt. Ich hatte vieles versucht in das Feld einzutragen, doch nichts funktionierte.

Danke für den Tipp mit dem Makro "ConfigPropChange". Doch versteh ich nicht ganz was das Makro machen soll bzw. beim testen rührte sich in den Eigenschaften nichts.

Ich habe auf MakroMania noch das Makro "32. Konfigurationsspezifische Eigenschaften nach Dateieigenschaften kopieren / verschieben" gefunden.
http://solidworks.cad.de/mm_32.htm
Doch dieses Funktioniert nur genau andersherum als ich es bräuchte.

Viele Grüße Daniel

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Daniel,

kannst du etwas genauer erklären was passieren soll? Theoretisch kannst du dir auch ein Macro schreiben welches du mit dem Taskmanager auf die gewünschten Dateien anwendest.

Gruß
Bernd

------------------
--- Man muß nicht alles wissen, man muß nur wissen wo es steht ---

Staatlich anerkannte Deutschniete 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Bernd,

es gäbe 2 Varianten um an mein Ziel zu gelangen.

Variante 1:
Bei allen Dateien die benutzerdefinierten Dateieigenschaften löschen. Ein Makro +pac4swx habe ich dafür.
Danach neue Eigenschaften wie in "Bild.jpg" bei allen Dateien in die konfigurationsspezifischen Eigenschaften schreiben, auch bei allen vorhandenen Konfigurationen.

Variante 2:
Bei allen Dateien die benutzerdefinierten Dateieigenschaften in die konfigurationsspezifischen Eigenschaften verschieben. Bei vorhandenen Konfiguration die Eigenschaften jeweils auch erstellen.

Viele Grüße Daniel

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Daniel,

hier mal ein Quick and Dirty Macro:

Code:

---

Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModel As ModelDoc2
Dim swModelDocExt As ModelDocExtension
Dim swCustProp As CustomPropertyManager

Dim sDocTitel As String

Dim vConfigNames    As Variant

Dim sPorpValBauteilnummer As String
Dim valout As String

Dim boolstatus As Boolean
Dim longstatus As Long

Dim i As Integer

Sub main()
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swModelDocExt = swModel.Extension

'Dokumentnamen ermitteln und Endung entfernen

sDocTitel = swModel.GetTitle
sDocTitel = Replace(sDocTitel, ".SLDPRT", "")

'Konfigurationsnamen ermitteln

vConfigNames = swModel.GetConfigurationNames()

'Bauteilnummer aus Benutzerdefinierten Eigenschaften auslesen

Set swCustProp = swModelDocExt.CustomPropertyManager("")
boolstatus = swCustProp.Get4("Bauteilnummer", False, sPorpValBauteilnummer, valout)

'Eigenschaften in Konfigurationsspezifischen Eigenschaften erstellen

    For i = 0 To UBound(vConfigNames)
       
        Set swCustProp = swModelDocExt.CustomPropertyManager(vConfigNames(i))
       
        boolstatus = swCustProp.Add3("Bezeichnung", 30, sDocTitel, True)
        boolstatus = swCustProp.Add3("Bauteilnummer", 30, sPorpValBauteilnummer, True)
        boolstatus = swCustProp.Add3("Material", 30, """SW-Material@@" + vConfigNames(i) + "@" + sDocTitel + ".SLDPRT""", True)
        boolstatus = swCustProp.Add3("Gewicht", 30, """SW-Mass@@" + vConfigNames(i) + "@" + sDocTitel + ".SLDPRT""", True)
   
    Next i
   
'Eigenschaften aus Benutzerdefinierten Eigenschaften entfernen
   
Set swCustProp = swModelDocExt.CustomPropertyManager("")

longstatus = swCustProp.Delete2("Bezeichnung")
longstatus = swCustProp.Delete2("Bauteilnummer")
longstatus = swCustProp.Delete2("Material")
longstatus = swCustProp.Delete2("Gewicht")

End Sub

---

Eine Verknüpfung zum Dateinamen gibt es in Parts glaub ich nicht, daher habe ich den Dokumentennamen ermittelt und dieser wird direkt eingetragen, die Eigenschaften werden auch aus den Benutzerdefinierten Eigenschaften entfernt da es hier sonst zu Problemen auf Zeichnungen kommen kann wenn Eigenschaften doppelt existieren.

Gruß
Bernd

------------------
--- Man muß nicht alles wissen, man muß nur wissen wo es steht ---

Staatlich anerkannte Deutschniete 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Bernd,

vielen vielen Dank für deine Bemühungen!
Klappt wunderbar!

Viele Grüße Daniel

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP