---

Hallo,

gibt es ein Makro mit diesem man Zeichnungen einzeln (wie bei einer DXF) auslesen kann? Eine weitere Frage: ein Makro oder Tool um einzelne Bauteile als STEP umzuwandeln ohne Öffnen und Speichern unter zu müssen.

Gruß techdot

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Schau dir mal das Makro Nr. 20 an...

------------------
Viele Grüße, THSEFA 

Peg: "Al! Du warst nicht besonders nett zu meiner Familie."
Al: "Die Natur auch nicht! Mach der Vorwürfe."

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

2012-02-28PDF-Export.jpg

Hallo techdot,

wenn du eine Zeichnung mit mehreren Blättern hast, dann kannst du SWX
mitteilen, welche Blätter gedruckt werden sollen. Sprich, die Funktion ist
also enthalten. In deinem Makro musst du dann die entsprechenden Blätter,
die du drucken möchtest, angeben. Dazu gibt es die Methode SetSheets des
IExportPdfData-Objekts, die du mit einem Array der zu druckenden Blätter
"füttern" möchtest. Am einfachsten schaust du dir das "Save File as PDF"-Beispiel
in der API-Hilfe an.

------------------
==========
Gruß
Andreas
==========

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo techdot,

Zitat:

---

Original erstellt von techdot:
Eine weitere Frage: ein Makro oder Tool um einzelne Bauteile als STEP umzuwandeln ohne Öffnen und Speichern unter zu müssen.

---

Das kann ich mir nur schwer vorstellen, wie das funktionieren soll, irgendwie müssen die Daten ja ausgelesen werden, dazu muss das Dokument geöffnet werden, und irgendwie willst du ja hinterher eine STEP Datei haben, also müssen die Daten irgendwie gespeichert werden ...

Ciao,
Stefan

------------------
Inoffizielle deutsche SolidWorks Hilfeseite    http://solidworks.cad.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo techdot,

Zitat:

---

Original erstellt von techdot:
Eine weitere Frage: ein Makro oder Tool um einzelne Bauteile als STEP umzuwandeln ohne Öffnen und Speichern unter zu müssen.

---

wie Stefan schon sagte, ist es ohne SWX wohl kaum möglich. Denkbar wären zwei Wege:

1. Du öffnest das Teil/ die BG und klickst dann auf einen Button, hinter dem sich ein kleines Makro zum Speichern unter STEP verbirgt.
2. Du hast ein externes Progrämmchen (z.B. unter VB.net o.a.), das dir einen Dateidialog zum Auswählen deiner SWX-Dateien anbietet. Das
Programm öffnet dann Solidworks sowie die einzelnen Dateien, speichert
diese dann als STEP-Dateien und schließt Solidworks wieder. Ist aber sicherlich
nicht in einer Viertelstunde zu erledigen 

Für Punkt 1. wäre z.B. das von THSEFA genannte Makro geeignet.

------------------
==========
Gruß
Andreas
==========

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

danke erst einmal für die Antworten. Das Makro Nr.20 ist nicht schlecht funktioniert aber nicht so wie ich das wollte.Bei SW ohne Makro kann ich eine Zeichnung mit mehreren Blättern die DXF Dateien als einzelne Blätter auslesen d.h. jedes Blatt eine DXF Datei. Dieses wollte ich auch für PDF Dateien. Beim "Speichern unter" für DXF Dateien gibt es die Einstellung " Alle Blätter in sperate Dateien exportieren" dies müsste es auch für PDF Dateien geben. Problematik STEP: Ich hatte mir gedacht das es ein Makro/Tool gibt wo man das Teil im Feature Baum aktiviert aus welchem man eine STEP erzeugen will und mit rechter Maus oder ausführen Makro eine STEP erzeugt wird.

Danke für die Antworten

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo und einen schönen tag technodot.

einen habe ich auch noch.
Drucken aus Verzeichniss.

Wenn du dann dort als Standard Drucker einen PDF Drucker wählst müsste das auch funktionieren.
PDF Drucker  =>> Free PDF oder Pdf Creatore oder....

Gruß
ThoMay

------------------
Hast du Fragen?
Brauchst du 
Schaut mal nach im Bereich
Alle Foren => Wissenstransfer.
oder
Konstrukteure Online hier bei CAD.de
Richtig fragen -
Nettiquette - Konstruktionshilfen - Systeminfo - Unities - CAD Freeware - Forenübersicht - 3D Modelle - SolidWorks Videos

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

SaveAsPDFSingle.zip

Hallo techdot,

ich habe mal mein DXF-/PDF-Speichern-Makro ein wenig an deine Forderungen
angepasst. Die PDF werden jetzt im Unterverzeichnis PDF der Zeichnung
gespeichert. Habe es mit drei Blättern getestet und es funktionierte 
Vielleicht ist es ja das, was du gesucht hast.

------------------
==========
Gruß
Andreas
==========

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo ad_man,

das sieht gut aus. Er legt ein Unterverzeichniss DXF und PDF an. In dem Verzeichniss DXF schreibt er die DXF Dateien so rein wie es sein soll aber das PDF Verzeichniss ist leer. Beim Umwandeln schmeist er den drucker an und druckt einen Ausschnitt der Zeichnung. Kann ich dich bitten nachzubessern? Ich danke vielmals :-)

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

SaveAsPDF-Single.zip

Guten Morgen,

man sollte hin und wieder auch die Speichern-Taste drücken...

Jetzt aber das Makro in richtig! Das andere Makro funktioniert nur in
Verbindung mit dem Adobe Acrobat - Drucker, weil es in SWX 2011 einen
Fehler bei der Ausgabe als PDF gab.

------------------
==========
Gruß
Andreas
==========

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

ich danke Dir ad_man vielmals. Es geht genau so wie ich es mir vorgestellt habe. Ich bin sehr erfreut. THSEFA ich danke dir auch für deinen Tipp. Ich kann hier super einfach von bestimmten Dateien STEP Daten schreiben. Ihr habt mir mit euren Hilfen und Tipps sehr viel Zeit erspart, ich bin euch überaus Dankbar. Vielen Vielen Dank.

Gruß techdot

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

auch wenn der Beitrag schon ein paar Jahre alt ist hoffe ich trotzdem auf Hilfe. 

und zwar geht es um das Makro was hier gepostet wurde. Ist es möglich dieses so zu ändern das nicht nur ein Ordner PDF erstellt wird. Sondern auch ein passender Unterordner der wie die Baugruppe heißt?

LG Robby

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

https://ww3.cad.de/foren/ubb/Forum2/HTML/033489.shtml

sieh mal hier nach, vielleicht ist da schon was davon dabei, habe aber nicht alle Funktionen auswendig im Kopf.

lg Martin

------------------
ich spiel noch immer gern mit Bauklötzen, nur sind sie jetzt teurer 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Robby,

wie genau sieht das aus? Der PDF-Ordner wird in das Verzeichnis gelegt,
wo sich deine Zeichnung befindet. Der Pfad wird in diesen Code-Zeilen
festgelegt. Diesen kannst du beliebig zusammensetzen.

Code:

---

    ' Zerlegen in Pfad und Dateiname ohne Extension (7 Zeichen)
    For i = Len(strDateinameLang) To 1 Step -1
        If Mid(strDateinameLang, i, 1) = "\" Then
            strPfad = Left(strDateinameLang, i)
            strDateiname = Mid(strDateinameLang, i + 1, Len(strDateinameLang) - i - 7)
            Exit For
        End If
    Next i
   
    ' PDF-Dateien sollen im Unterverzeichnis PDF abgespeichert werden;
    strPDFPfad = strPfad + "PDF\"

---

Wenn du deine PDF unter C:\<Name der Baugruppe>\PDF abgespeichert haben
möchtest, dann lautet der entsprechende Code

   

Code:

---

strPDFPfad = "C:\" + strDateiname + "\PDF\"

---

Du kannst also deinen Pfad entsprechend "zusammenbauen".

------------------
==========
Gruß
Andreas
==========

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

1.JPG 2.JPG

Hallo 

danke erstmal für die Antwort. Hab mal paar Bilder angehangen wie unsere Ordner Struktur derzeit aussieht. Dort sieht man auch den Ordner PDF durch das neue Makro. nur soll in dem Ordner dann wieder ein Ordner erstellt werden der genau wie die Zeichnung heißt. Hab grad etwas rum probiert. Aber hab es nicht hinbekommen :-D

lg Robby

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin,

dann versuche es mal mit

   

Code:

---

strPDFPfad = strPfad + "PDF\" + strDateiname + "\"

---

Sollte klappen 

------------------
==========
Gruß
Andreas
==========

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

3.JPG

Huhu 

bekomme dann Laufzeitfehler 76: Pfad nicht gefunden.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

4.JPG

So klappt es fast. Er erstellt den Ordner aber der bleibt leer. Die PDFs liegen dann nach wie vor im PDF ordner

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

DrawingSaveAs.JPG OrdnerDialog1.jpg

Du kannst auch DrawingSaveAs vom SWXHelper verwenden.

Wenn du "Formate in Unterordner" einhakst erzeugt er im angegebenen Zielordner für jedes Format auch einen eigenen Unterordner.

Du wirst beim setzen des Speicherpfades Eigenständig den Ordner erzeugen müssen.

------------------
HOMEPAGE | SWXTools.de - SWXHelper für SOLIDWORKS
KONTAKT | support@swxtools.de
FACEBOOK | facebook.com/SWXHelper
TWITTER | twitter.com/SWXTools

[Diese Nachricht wurde von deckelmaho am 13. Okt. 2021 editiert.]

[Diese Nachricht wurde von deckelmaho am 13. Okt. 2021 editiert.]

[Diese Nachricht wurde von deckelmaho am 13. Okt. 2021 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo deckelmaho

Das hab ich auch schon gefunden. Das ist aber leider nicht genau das was ich möchte. Es soll ein Unterordner erstellt werden der wie die Zeichnung heiß.

Trotzdem Danke  

lg robby

Edit: es wäre super wenn ich den Ordner nicht erst erstellen müsste 

[Diese Nachricht wurde von Mr.Robi am 13. Okt. 2021 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Dann schaue dir doch mal bitte mit dem Debugger den Inhalt der
Variablen strPDFPfad und strPDF-Dateiname an. Oder du stellst deinen
aktuellen Code mal komplett hier ein, dann kann ich da drüber schauen.

------------------
==========
Gruß
Andreas
==========

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo 

Ist im Grunde noch der Original Code. Die Befehlszeilen die ich Probiert habe hab ich ausgeklammert

Code:

---

' **********************************************************************
' * Makro erzeugt aus dem aktiven Zeichnungsdokument für alle Blätter
' * eine PDF Datei im Unterverzeichnis PDF der Zeichnung. Es werden alle
' * Blätterunter dem Namen kombiniert mit dem Blattnamen abgespeichert.
' *
' * Basiert auf einer Vorlage von:
' *
' * 05.04.2001 Stefan Berlitz (stefan.berlitz@solidworks.cad.de)
' * http://solidworks.cad.de
' * http://swtools.cad.de
' **********************************************************************
Option Explicit

Dim swApp              As SldWorks.SldWorks
Dim swDrawingDoc        As SldWorks.ModelDoc2
Dim swSheet            As SldWorks.Sheet
Dim swModelDocExt      As SldWorks.ModelDocExtension
Dim swExportPDFData    As SldWorks.ExportPdfData
Dim swPs                As SldWorks.PageSetup

Dim bReturn            As Boolean
Dim bCollate            As Boolean

Dim vSheets            As Variant
Dim vSheetProps        As Variant
Dim vPageArray          As Variant

Dim strDateiname        As String
Dim strPDFDateiname    As String
Dim strDateinameLang    As String
Dim strPfad            As String
Dim strPDFPfad          As String
Dim strMsgtxt          As String
Dim strSheetName        As String
Dim strPrinter          As String

Dim i                  As Long
Dim lAnzahlBl          As Long
Dim lErrors            As Long
Dim lWarnings          As Long
Dim lFarbe              As Long
Dim lPageArray          As Long
Dim lCopies            As Long

Dim intReturn          As Integer

Sub main()
   
    'Anbindung an SWX
    Set swApp = Application.SldWorks
    Set swDrawingDoc = swApp.ActiveDoc
    strMsgtxt = ""
   
    ' wenn keine Zeichnung aktiv wird das Makro wieder beendet
    If (swDrawingDoc.GetType <> swDocDRAWING) Then
        MsgBox "Nur für Zeichnungen geeignet"
        Exit Sub
    End If
   
    ' Prüfung, ob Zeichnung gespeichert werden muss. Falls Zeichnung nicht
    ' gespeichert wird, Abbruch!
    If swDrawingDoc.GetSaveFlag Then
        intReturn = swApp.SendMsgToUser2("Soll die Zeichnung gesichert werden?", swMbQuestion, swMbYesNo)
        If intReturn = swMbHitYes Then
            bReturn = swDrawingDoc.Save3(swSaveAsOptions_Silent, lErrors, lWarnings)
        Else
            intReturn = swApp.SendMsgToUser2("Bitte die Zeichnung speichern!", swMbInformation, swMbOk)
            Exit Sub
        End If
    End If
   
    ' die Anzahl der Blätter holen, und dann in der Schleife eines nach
    ' dem anderen Abspeichern. Dazu ein Handle auf das aktuelle Blatt holen
    lAnzahlBl = swDrawingDoc.GetSheetCount
    Set swSheet = swDrawingDoc.GetCurrentSheet
   
    ' damit die DXF anschließend im Unterverzeichnis PDF der Zeichnung gespeichert
    ' werden, muss der Pfad ermittelt werden.
    strDateinameLang = swDrawingDoc.GetPathName
   
    ' Zerlegen in Pfad und Dateiname ohne Extension (7 Zeichen)
    For i = Len(strDateinameLang) To 1 Step -1
        If Mid(strDateinameLang, i, 1) = "\" Then
            strPfad = Left(strDateinameLang, i)
            strDateiname = Mid(strDateinameLang, i + 1, Len(strDateinameLang) - i - 7)
            Exit For
        End If
    Next i
   
    ' PDF-Dateien sollen im Unterverzeichnis DXF abgespeichert werden;
   
    'strPDFPfad = strPfad + "PDF\" + strDateiname + "\"
    'strPDFPfad = strPfad + "PDF\" + strDateiname
    strPDFPfad = strPfad + "PDF\"
   
    ' Prüfung, ob die Verzeichnisse überhaupt existiert, da sie sonst angelegt
    ' werden müssen
    If Len(Dir(strPDFPfad, vbDirectory)) = 0 Then
        MkDir (strPDFPfad)
    End If
   
    ' wenn mehr als ein Blatt da ist könnte es sein, dass wir nicht auf
    ' Blatt 1 sind. In einem Makro müssen wir jetzt einen Trick machen, um
    ' auf das erste Blatt zurückzukommen.
    ' Dazu immer wieder ein Blatt zurückspringen und dabei den Blattnamen
    ' vergleichen; wenn der gleich bleibt haben wir das erste Blatt erreicht.
    strSheetName = swSheet.GetName
    For i = 1 To lAnzahlBl - 1
        swDrawingDoc.SheetPrevious
        Set swSheet = swDrawingDoc.GetCurrentSheet
        If (strSheetName = swSheet.GetName) Then
            Exit For
        End If
    Next i
       
    ' jetzt sind wir garantiert auf dem ersten Blatt und können jetzt eins
    ' nach dem anderen Abspeichern
    For i = 1 To lAnzahlBl
       
        ' wir wollen alle Blätter als PDF mit den eingestellten Optionen abspeichern
        Set swSheet = swDrawingDoc.GetCurrentSheet
        strSheetName = swSheet.GetName
        strPDFDateiname = strPDFPfad & strDateiname & " - " & strSheetName & ".pdf"
       
        ' dann erfolgt das Speichern als PDF mittels swModelDocExt.SaveAs
        ' wenn alles geklappt hat, wird TRUE zurückgeliefert, ansonsten FALSE
       
        Set swModelDocExt = swDrawingDoc.Extension
        Set swExportPDFData = swApp.GetExportFileData(1)
       
        bReturn = swExportPDFData.SetSheets(swExportData_ExportCurrentSheet, Nothing)
       

        bReturn = swModelDocExt.SaveAs(strPDFDateiname, swSaveAsCurrentVersion, swSaveAsOptions_Copy, _
                    swExportPDFData, lErrors, lWarnings)
       
        If bReturn Then
            strMsgtxt = strMsgtxt & "erfolgreich gespeichert: " & strDateiname & " - " & swSheet.GetName & _
                    ".pdf" & Chr$(10) & Chr$(13)
        Else
            intReturn = swApp.SendMsgToUser2("FEHLER BEIM SPEICHERN VON " & strDateiname & " - " & swSheet.GetName & _
                  ".pdf" & Chr$(10) & Chr$(13), swMbInformation, swMbOk)
            strMsgtxt = strMsgtxt & "*** FEHLER bei: " & strDateiname & " - " & swSheet.GetName & _
                    ".pdf" & Chr$(10) & Chr$(13)
        End If
       
       
        ' und wenn noch Blätter kommen dieses aktivieren
        If lAnzahlBl > i Then
            swDrawingDoc.SheetNext
        End If
    Next i
   
    ' und noch die Zusammenfassung übers Speichern ausgeben
    intReturn = swApp.SendMsgToUser2(strMsgtxt, swMbInformation, swMbOk)
   
End Sub

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Code:

---

Sub main()
  
    'Anbindung an SWX
    Set swApp = Application.SldWorks
    Set swDrawingDoc = swApp.ActiveDoc
    strMsgtxt = ""
  
    ' wenn keine Zeichnung aktiv wird das Makro wieder beendet
    If (swDrawingDoc.GetType <> swDocDRAWING) Then
        MsgBox "Nur für Zeichnungen geeignet"
        Exit Sub
    End If
  
    ' Prüfung, ob Zeichnung gespeichert werden muss. Falls Zeichnung nicht
    ' gespeichert wird, Abbruch!
    If swDrawingDoc.GetSaveFlag Then
        intReturn = swApp.SendMsgToUser2("Soll die Zeichnung gesichert werden?", swMbQuestion, swMbYesNo)
        If intReturn = swMbHitYes Then
            bReturn = swDrawingDoc.Save3(swSaveAsOptions_Silent, lErrors, lWarnings)
        Else
            intReturn = swApp.SendMsgToUser2("Bitte die Zeichnung speichern!", swMbInformation, swMbOk)
            Exit Sub
        End If
    End If
  
    ' die Anzahl der Blätter holen, und dann in der Schleife eines nach
    ' dem anderen Abspeichern. Dazu ein Handle auf das aktuelle Blatt holen
    lAnzahlBl = swDrawingDoc.GetSheetCount
    Set swSheet = swDrawingDoc.GetCurrentSheet
  
    strDateinameLang = swDrawingDoc.GetPathName
    ' Statt mit einer Schleife jedes einzelne Zeichen eines Strings
    ' zu druchlaufen arbeite ich gerne mit Arrays, Split und Join
    ' Aus meiner Sicht zuverlässiger
    Dim PfadSegmente() As String
    PfadSegmente = Split(strDateinameLang, "\")
    Dim Index As Integer
    ReDim strPfade(UBound(PfadSegmente) - 1) As String
    Dim DateiNamePlusExtension() As String
    DateiNamePlusExtension = Split(PfadSegmente(UBound(PfadSegmente)), ".")
    For i = 0 To UBound(strPfade)
        strPfade(i) = PfadSegmente(i)
    Next i
    strPfad = Join(strPfade, "\")
    Dim strDateiNameOhneExtension As String
    strDateiNameOhneExtension = DateiNamePlusExtension(LBound(DateiNamePlusExtension))

   
    strPDFPfad = strPfad + "\" + strDateiNameOhneExtension + "\PDF\"
  
    ' Prüfung, ob die Verzeichnisse überhaupt existiert, da sie sonst angelegt
    ' werden müssen
    Dim Dummy As Variant
    Dim strCheckPath As String

    strCheckPath = ""
    For Each Dummy In Split(strPDFPfad, "\")
        strCheckPath = strCheckPath & Dummy & "\"
        If Len(Dir(strCheckPath, vbDirectory)) = 0 Then MkDir strCheckPath
    Next
  
    ' wenn mehr als ein Blatt da ist könnte es sein, dass wir nicht auf
    ' Blatt 1 sind. In einem Makro müssen wir jetzt einen Trick machen, um
    ' auf das erste Blatt zurückzukommen.
    ' Dazu immer wieder ein Blatt zurückspringen und dabei den Blattnamen
    ' vergleichen; wenn der gleich bleibt haben wir das erste Blatt erreicht.
    strSheetName = swSheet.GetName
    For i = 1 To lAnzahlBl - 1
        swDrawingDoc.SheetPrevious
        Set swSheet = swDrawingDoc.GetCurrentSheet
        If (strSheetName = swSheet.GetName) Then
            Exit For
        End If
    Next i
      
    ' jetzt sind wir garantiert auf dem ersten Blatt und können jetzt eins
    ' nach dem anderen Abspeichern
    For i = 1 To lAnzahlBl
      
        ' wir wollen alle Blätter als PDF mit den eingestellten Optionen abspeichern
        Set swSheet = swDrawingDoc.GetCurrentSheet
        strSheetName = swSheet.GetName
        strPDFDateiname = strPDFPfad & strDateiNameOhneExtension & " - " & strSheetName & ".pdf"
      
        ' dann erfolgt das Speichern als PDF mittels swModelDocExt.SaveAs
        ' wenn alles geklappt hat, wird TRUE zurückgeliefert, ansonsten FALSE
      
        Set swModelDocExt = swDrawingDoc.Extension
        Set swExportPDFData = swApp.GetExportFileData(1)
      
        bReturn = swExportPDFData.SetSheets(swExportData_ExportCurrentSheet, Nothing)
      

        bReturn = swModelDocExt.SaveAs(strPDFDateiname, swSaveAsCurrentVersion, swSaveAsOptions_Copy, _
                    swExportPDFData, lErrors, lWarnings)
      
        If bReturn Then
            strMsgtxt = strMsgtxt & "erfolgreich gespeichert: " & strDateiName & " - " & swSheet.GetName & _
                    ".pdf" & Chr$(10) & Chr$(13)
        Else
            intReturn = swApp.SendMsgToUser2("FEHLER BEIM SPEICHERN VON " & strDateiName & " - " & swSheet.GetName & _
                  ".pdf" & Chr$(10) & Chr$(13), swMbInformation, swMbOk)
            strMsgtxt = strMsgtxt & "*** FEHLER bei: " & strDateiName & " - " & swSheet.GetName & _
                    ".pdf" & Chr$(10) & Chr$(13)
        End If
      
      
        ' und wenn noch Blätter kommen dieses aktivieren
        If lAnzahlBl > i Then
            swDrawingDoc.SheetNext
        End If
    Next i
  
    ' und noch die Zusammenfassung übers Speichern ausgeben
    intReturn = swApp.SendMsgToUser2(strMsgtxt, swMbInformation, swMbOk)
  
End Sub

---

[Diese Nachricht wurde von riesi am 14. Okt. 2021 editiert.]

[Diese Nachricht wurde von riesi am 14. Okt. 2021 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo riesi,

nicht ganz das was ich wollte. Aber im Grunde genau das was ich brauche     
Mit der lösung komm ich sehr gut klar

vielen dank

lg robby

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP