---

Hallo,

gibt es die Möglichkeit, über ein Makro auf alle horizontalen Linien mit 6mm Länge in einer Zeichnung, mittig einen Punkt zu setzen?

Gruß Ronald

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Mit etwas Makroprogrammierung zu machen. Über INQ_SELECTED_ELEM alle Linien erfassen und danach in einer Loop (INQ_NEXT_ELEM) abarbeiten

------------------
kjw

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zum Beispiel

Code:

---

DEFINE Punkt_auf_Linie
  LOCAL Ctr
  LOCAL Length
  LOCAL Nbr
  LOCAL P01
  LOCAL P02
  LOCAL Tol
 
  LET Length 6
  LET Tol 0.001

  INQ_SELECTED_ELEM SELECT LINES ALL CONFIRM
  LET Nbr ( INQ 14 )
  LET Ctr 1

  WHILE (Ctr <= Nbr)
    LET P01 ( INQ 101 )
    LET P02 ( INQ 102 )
    IF (((LEN (P01-P02)) - Length) < Tol)
      POINT ((P01+P02)/2)
    END_IF
    INQ_NEXT_ELEM
    LET Ctr (Ctr+1)
  END_WHILE

  END

END_DEFINE

---

------------------

http://kotom.eng.free.fr/

[Diese Nachricht wurde von Kotom-Eng am 23. Jul. 2024 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Kotom-Eng,

das sieht sehr gut aus.
Da ich die Punkte auf "Fadenkreuze" setze, habe ich diese dann doppelt.
1x für horizontal und 1x für vertikal.
Kann man ja dann bereinigen.

Vielen Dank
Ronald

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

Ich verstehe nicht, was Sie meinen. Warum werden die Punkte verdoppelt?

------------------

http://kotom.eng.free.fr/

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Fadenkreuz.PNG

Hallo,

das Makro nimmt alle Linien mit 6 mm Länge.
Bei mir Kreuzen sich 2 Linien, also gibt es 2 Punkte.
Seltsamer weise nimmt das Makro auch Linien die zusammen 6 mm ergeben.
Also z.B. 2 x 3mm. Dann wird der Punkt Mittig auf einer der beiden Linien gesetzt.
Daher habe ich jetzt noch die Trennfunktion deaktiviert.

DEFINE Punkt_auf_Linie
  LOCAL Ctr
  LOCAL Length
  LOCAL Nbr
  LOCAL P01
  LOCAL P02
  LOCAL Tol

  LET Length 6
  LET Tol 0.001

  INQ_SELECTED_ELEM SELECT LINES YELLOW CONFIRM
  LET Nbr ( INQ 14 )
  LET Ctr 1

  WHILE (Ctr <= Nbr)
    LET P01 ( INQ 101 )
    LET P02 ( INQ 102 )
    IF (((LEN (P01-P02)) - Length) < Tol)
SPLITTING OFF
      POINT PENSIZE 0 cyan DASH_CENTER ((P01+P02)/2)
    END_IF
    INQ_NEXT_ELEM
    LET Ctr (Ctr+1)
CLEAN_DRAWING
CLEAN_DUPLICATE_GEOMETRY
0.0
CONFIRM
  END_WHILE

  END

END_DEFINE

Gruß Ronald

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von rkb:
Da ich die Punkte auf "Fadenkreuze" setze, habe ich diese dann doppelt.
1x für horizontal und 1x für vertikal.
Kann man ja dann bereinigen. 

---

Nun ja .  wenn mich meine sommerlichen Tomaten auf den Augen nicht täuschen fehlt da noch die Bedingung

Zitat:

---

alle horizontalen Linien

---

Der IF braucht noch ein AND welches ((abs (x_of p01) - (x_p02)) < Tol) zusätzlich prüft. (pseudo Makro code)

Kriegt'de hin, rkb!

------------------
● Firefox ESR ● Java Forum Stuttgart JUGS ● OSD Hilfeseite (de) / help page (en) ● NotePad++ ● BuFDi ●

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Wolfgang,
und wie sähe die Lösung in Annotation aus?
Sehr viel komplizierter! Deshalb mein Wunsch in einem anderen Thread, das Drafting durch PTC geöffnet werden sollte. Mit der Demo- Version kann man nicht viel machen.

------------------
kjw

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von karl-josef_wernet:
und wie sähe die Lösung in Annotation aus?

---

Wäre im Annotation halt so:

Code:

---

(sd-execute-annotator-command :cmd "Punkt_auf_Linie")

---

So lange ein ME10 Makro nichts / nicht viel vom Anwender abfragt, kann man den Makro auch aus dem Annotation heraus nutzen. Ggf. muss man über 'current part' / das Sheet-Konzept nachdenken. Aber nach der 3. Makro adaption hat man das raus.

Ein Guter Annotöter kann halt ME10 Makros. 😏

------------------
● Firefox ESR ● Java Forum Stuttgart JUGS ● OSD Hilfeseite (de) / help page (en) ● NotePad++ ● BuFDi ●

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo RKB,

Für Fälle, in denen die Leine kürzer als 6 mm ist, habe ich ABS hinzugefügt.
SPLITTING OFF wird vor WHILE gestellt. Es macht keinen großen Unterschied, aber es ist besser. SPLITTING ON wurde am Ende hinzugefügt, es scheint für Sie die Norm zu sein.
CLEAN_DRAWING wird nach END_WHILE eingefügt. Es macht keinen großen Unterschied, aber es ist besser.

Hallo Wolfgang,

Die Zusatzbedingung ((ABS (X_OF P01) - (X_OF P02)) < TOL) bedeutet, dass die Linie vertikal sein muss, oder? Die anderen 6-mm-Linie sind in diesem Fall also nicht betroffen.

Code:

---

DEFINE Punkt_auf_Linie
  LOCAL Ctr
  LOCAL Length
  LOCAL Nbr
  LOCAL P01
  LOCAL P02
  LOCAL Tol
 
  LET Length 6
  LET Tol 0.001

  INQ_SELECTED_ELEM SELECT LINES ALL CONFIRM
  LET Nbr ( INQ 14 )
  LET Ctr 1
  SPLITTING OFF

  WHILE (Ctr <= Nbr)
    LET P01 ( INQ 101 )
    LET P02 ( INQ 102 )
    IF (( ABS (( LEN (P01-P02)) - Length)) < Tol)
      POINT ((P01+P02)/2)
    END_IF
    INQ_NEXT_ELEM
    LET Ctr (Ctr+1)
  END_WHILE
 
  CLEAN_DRAWING CLEAN_DUPLICATE_GEOMETRY 0.0 CONFIRM END
  SPLITTING ON

END_DEFINE

---

------------------

http://kotom.eng.free.fr/

[Diese Nachricht wurde von Kotom-Eng am 26. Jul. 2024 editiert.]

[Diese Nachricht wurde von Kotom-Eng am 26. Jul. 2024 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Wolfgang,

hat ein wenig gedauert, aber ich habe es hin bekommen.
Da jetzt nur noch auf alle horizontalen Linien ein Punkt gesetzt wird, brauch ich die bereinigung der doppelten Elemente nicht mehr!

DEFINE Punkt_auf_Linie
  LOCAL Ctr
  LOCAL Length
  LOCAL Nbr
  LOCAL P01
  LOCAL P02
  LOCAL Tol

  LET Length 6
  LET Tol 0.001

  INQ_SELECTED_ELEM SELECT LINES YELLOW CONFIRM
  LET Nbr ( INQ 14 )
  LET Ctr 1
  SPLITTING OFF

  WHILE (Ctr <= Nbr)
    LET P01 ( INQ 101 )
    LET P02 ( INQ 102 )
    IF (ABS (LEN (X_OF P01 - X_OF P02) - Length) < Tol)
      POINT cyan DASH_CENTER ((P01+P02)/2)
    END_IF
    INQ_NEXT_ELEM
    LET Ctr (Ctr+1)
  END_WHILE

  SPLITTING ON

END_DEFINE

Gruß und Danke
Ronald

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von rkb:
hat ein wenig gedauert, aber ich habe es hin bekommen. 

---

gut, halt, also Jein. 

das delta-X von zwei Punkten kann auch bei einer nicht horizontalen Linie 6 mm sein . 

Du musst schon beides checken:

sinngemäß:

Code:

---

IF (and ((ABS ((LEN (P01-P02)) - Length)) < Tol)  { length of line, should be ~6mm }
        ((ABS (Y_OF P01 - Y_OF P02)) < Tol)      { horizontal line, dy should be ~0mm }
        )
  ...

---

- just written, not tested!

------------------
● Firefox ESR ● Java Forum Stuttgart JUGS ● OSD Hilfeseite (de) / help page (en) ● NotePad++ ● BuFDi ●

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Wolfgang,
auch nicht getestet...

IF ( ((ABS ((LEN (P01-P02)) - Length)) < Tol)  { length of line, should be ~6mm }
    AND
    ((ABS (Y_OF P01 - Y_OF P02)) < Tol)      { horizontal line, dy should be ~0mm }
  )
  ...

aber das AND sollte schon zwischen den beiden Vergleichen sein.

------------------
Homepage: www.me10-makros.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von r.hoffmann:
aber das AND sollte schon zwischen den beiden Vergleichen sein.

---

😄 da hat wohl der LISPler in mir die Überhand gehabt. 😏

------------------
● Firefox ESR ● Java Forum Stuttgart JUGS ● OSD Hilfeseite (de) / help page (en) ● NotePad++ ● BuFDi ●

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP