---

Hallo,
ich möchte einen Sketch in einem Geometrischen Set erzeugen.
Ich habe mein Catscript jetzt so weit, dass es einen Sketch im Main-Body erzeugt.
Wie kann ich das Ergebnis manipulieren, dass das Ziel anders ist.
Der Punkt scheint anders generiert zu werden.

Code:

---

'Fügt in ein geöffnetes Part ein Geometrisches Set, einen Sketch und einen Punkt ein.
Option Explicit

Sub CATMain()
    Dim oDoc As Document
    Dim oPart As Part
    Dim body1 As Body
    Dim Sketches1 As Sketches
    Dim reference1 As Reference
    Dim Sketch1    'As Sketch
    Dim arrayOfVariantOfDouble1(8)
    Dim factory2D1 As Factory2D
    Dim o2DFactory    'As Factory2D
    Dim oPoint2D As Point2D
    Dim oTargetPart As PartDocument
    Dim HybridShapeFactory1 As HybridShapeFactory
    Dim HybridBodies1 As HybridBodies
    Dim oGeoset
    Dim HybridShapePointCoord1 As HybridShapePointCoord

    Set oDoc = CATIA.ActiveDocument
    Set oPart = oDoc.Part ' aktives part holen
    Set HybridShapeFactory1 = oPart.HybridShapeFactory
    Set HybridBodies1 = oPart.HybridBodies
   
    Set oGeoset = HybridBodies1.Add
    oGeoset.Name = "Generated Set.1"
    Set HybridShapeFactory1 = oPart.HybridShapeFactory
    Set HybridShapePointCoord1 = HybridShapeFactory1.AddNewPointCoord(5, 7, 11)
    oGeoset.AppendHybridShape HybridShapePointCoord1 
    hybridShapePointCoord1.Name = "Generated Point.1"

    Set Body1 = oPart.MainBody
'  Set Sketches1 = HybridShapeFactory1.Sketches
    Set Sketches1 = Body1.Sketches
    Set Reference1 = oPart.OriginElements.PlaneXY
   
    Set Sketch1 = Sketches1.Add(reference1)
    Sketch1.Name = "Generated Sketch.1"

    oPart.InWorkObject = Sketch1
    Set factory2D1 = Sketch1.OpenEdition()
    Set o2DFactory = Sketch1.Factory2D
    Set oPoint2D = o2DFactory.CreatePoint(10, 22)
    Sketch1.CloseEdition

oPart.Update
End Sub

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus

Du musst die Skizze in der Sketch-Collection des HybridBodies (GeoSet) erzeugen und nicht im Body:

Code:

---

Dim oSketches As Sketches
Set oSketches = oGeoset.HybridSketches
Set Sketch1 = oSketches.Add(reference1)

---

Alle andern Elemente in einem GeoSet musst du mit AppendHybridShape rein holen (die Skizzen bilden da eine Ausnahme)

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Genau so habe ich es mir gewünscht.
Danke.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP