---

Formeln_00_Oberbaugruppe.png

Hallo,
Ich habe ein kleines Problem mit ein Makro von mir das bei großen Baugruppen immer langsamer wird und manchmal auch ein Fehler ausgibt.
Das Problem ist der Teil der mir Parameter aus der Obersten Baugruppe auslesen soll.
Mein Code durchsucht aber scheinbar alle vorhandenen Parameter und nicht nur die von der Obersten Baugruppe. Daher kommt es auch vor, wenn der Parametername nochmal in einer Unterbaugruppe vorkommt, dass der Wert der Unterbaugruppe ausgegeben wird. Es scheint der erste Parameter genommen zu werden der den Namen aufweist.

Bild: Bei NrModul wird 1 ausgegeben ich möchte aber 0 haben.
Wie muss ich mein Code abändern das nur die Oberbaugruppenparameter durchsucht werden?

Sub CATMain()
Set productDocument1 = CATIA.ActiveDocument
Set product1 = productDocument1.Product
Set parameters1 = product1.Parameters

Set strParam1 = parameters1.Item("TV_Nr")
Name_TV = strParam1.ValueAsString
Set strParam2 = parameters1.Item("NrModul")
Nummer_Modul = strParam2.Value

MsgBox Name_TV & vbCrLf & Nummer_Modul
End Sub

Gruß Windninja

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

versuche es mal so:

Sub CATMain()
Set productDocument1 = CATIA.ActiveDocument
Set product1 = productDocument1.Product
Set parameters1 = product1.Parameters.RootParameterSet.DirectParameters

Set strParam1 = parameters1.Item("TV_Nr")
Name_TV = strParam1.ValueAsString
Set strParam2 = parameters1.Item("NrModul")
Nummer_Modul = strParam2.Value

MsgBox Name_TV & vbCrLf & Nummer_Modul
End Sub

Gruß
Randle

[Diese Nachricht wurde von Randle am 02. Aug. 2016 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi Ninja,

wie der Marcus schon zeigt, musst die/den Parameter genauer angeben.
Die nachfolgende Routine listet zuerst die zwei Produkt-Parameter aus,
danach alle(wie von Dir ursprünglich vorgegeben).
Den Code hab ich aus einem anderen Makro kannibalisiert; deswegen der 'Select Case'.
Zu beachten ist, dass bei der zweiten Variante NrModul und TV_Nr zweimal vorkommen.

Code:

---

Sub CATMain()

Dim oAD As Document                          'active doc
  Dim oDrawSourcePS As ParameterSet
  Dim oDrVw As DrawingView
  Dim strPSName As String                      'parameter set name
  Dim oRootPS As ParameterSet                  'root parameterset
  Dim oAllPSs As Parameters                    'all parameters root
  Dim strParmName As String                    'parameter bezeichnung
  Dim oParent As Object                        'part, product or drawing
  Dim n As Integer
  Dim oPSsDummy As Parameters
 
  Set oAD = CATIA.ActiveDocument
  CATIA.Windows.Arrange catArrangeTiledVertical
 
  Select Case TypeName(oAD)
      Case "DrawingDocument"              'drawing
        Set oRootPS = oAD.Parameters.RootParameterSet
        Set oAllPSs = oAD.Parameters
        If oAD.Sheets.ActiveSheet.IsDetail = False Then
            If oAD.Sheets.ActiveSheet.Views.Count > 2 Then                '3. view is linked to product
              Set oDrVw = oAD.Sheets.ActiveSheet.Views.Item(3)
              Set oDrawSourcePS = oDrVw.GenerativeBehavior.Document.Parent.Product.Parameters.RootParameterSet
            End If
        Else
            MsgBox "Switch to drawing sheet"
        End If
    '    Set oParent = oAD
      Case "PartDocument"                'single part
        Set oRootPS = oAD.Part.Parameters.RootParameterSet
        Set oAllPSs = oAD.Part.Parameters
        Set oParent = oAD.Part
    '    Set oPubParent = oAD.Part.Parent.Product
      Case "ProductDocument"              'assy
        Set oRootPS = oAD.Product.Parameters.RootParameterSet
        Set oAllPSs = oAD.Product.Parameters
        Set oParent = oAD.Product
  '      Set oPubParent = oAD.Product
  End Select
 
  Set oPSsDummy = oRootPS.DirectParameters
  For n = 1 To oPSsDummy.Count
      Debug.Print oPSsDummy.Item(n).Name, oPSsDummy.Item(n).ValueAsString
  Next
 
  Set oPSsDummy = oAllPSs
  For n = 1 To oPSsDummy.Count
      Debug.Print oPSsDummy.Item(n).Name, oPSsDummy.Item(n).ValueAsString
  Next
 
End Sub

---

Tschau,
Joe

------------------
Inoffizielle Catia Hilfeseite

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke Randle, genau so wollte ich das.

Gruß Windninja

[Diese Nachricht wurde von Windninja am 02. Aug. 2016 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP