---

Hallo,

gibt es eine Möglichkeit, die kollisionsanalyse per VBA zu steuern? Ich habe schon einiges Probiert, aber noch nichts hinbekommen.

Der Makro-Rekorder zeichnet hierzu nichts auf...

Ich konnte zwar per

Code:

---

CATIA.StartCommand "Clash"

---

den Clah-dialog aufrufen, muss aber dann per Hand auf "Apply" klicken, damit das auch funktioniert. Ich würde es gerne vollständig automatisieren.

Danke im vorraus

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Schau dir mal in der V5Automation.chm dazu bei der SPAWorkbench die Objekte "Clash" an.

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hey,

Problem schon gelöst?

Hier mal ein Code, der aus der Automation entnommen worden ist und etwas modifiziert ist. Hab ich letztens grad mal auch benötigt.

Code:

---

Sub CatMain()

'Select the Parts
Set selection1 = CATIA.ActiveDocument.Selection
selection1.Search "Type=Part & Name = *,all" 'Suche nach den Parts

'Retrieve the Clashes collection
Dim cClashes As Clashes
Set cClashes = CATIA.ActiveDocument.Product.GetTechnologicalObject("Clashes")

'Create a clash with selected components and compute it
Dim oClash As Clash
Set oClash = cClashes.AddFromSel
oClash.ComputationType = catClashComputationTypeAgainstAll    'or ...XXX other rules
oClash.InterferenceType = catClashInterferenceTypeClearance   'or ...Contact without Clearance
oClash.Clearance = 5                                          'Insert clearance value
oClash.Compute
      
'Filter conflicts
Dim cConflicts As Conflicts
Set cConflicts = oClash.Conflicts

Dim I As Integer
For I = 1 To cConflicts.Count
    Dim oConflict As Conflict
    Set oConflict = cConflicts.Item(I)
    If (oConflict.Type = catConflictTypeClearance) Then
        oConflict.Status = catConflictStatusRelevant
        oConflict.Comment = "Clearance fell below " & oClash.Clearance & "mm"
    ElseIf (oConflict.Type = catConflictTypeContact) Then
        oConflict.Status = catConflictStatusRelevant
        oConflict.Comment = "Contact"
    ElseIf (oConflict.Type = catConflictTypeClash) Then
        oConflict.Status = catConflictStatusRelevant
        oConflict.Comment = "Clash " & Int(oConflict.Value * 100) / 100 & "mm"   'Value with two decimal places
    End If
Next
'MsgBox Output if no Conflict was detected
If (cConflicts.Count = 0) Then
    MsgBox "No Conflicts.", vbInformation, "Output"
End If

End Sub

'Only for Information, if desired
'Export als .xml
'Dim ThePath As String
'oClash.Export CatClashExportTypeXMLResultOnly, "Dateiname mit Pfad"

---

Da kann man dann auch gleich die nötigen Kommentare automatisch dazu verfassen lassen.

Grüße

[Diese Nachricht wurde von SteelNinja am 17. Feb. 2016 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP