---

Hallo,

ich suche ein Makro das mir in einer Zeichnung bei 1 beginnend bei jedem Mausklick die Zahl ausgibt und eins hochzählt.
(1, 2 ,3...usw)

Das geht auch mit der Ballon Funtion nur hängt da der Leader mit dran.
Es sollte nur die Zahl sichtbar sein.

Es sollte Blatt übergreifend möglich sein.
Wenn ich auf Blatt1 mit der Zahl 5 aufhöre sollte es auf Blatt2 mit der Zahl 6 weitegehen.

Also eigentlich genau die gleich Funktionalität wie beim Ballon nur ohne Leder und Punkt.

Ich hoff eich konnte das verständlich erklären was mir so vorschwebt.

Schonmal vorab besten Dank und Gruß

Micha

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Zeus34,

Ich glaube, das könnte es sein:

Sub CATMain()

Dim Status
Dim Position(1)
Dim drawingDocument1 As DrawingDocument
Set drawingDocument1 = CATIA.ActiveDocument

CATIA.ActiveWindow.ActiveViewer.Reframe  'Fit in Page
Status = drawingDocument1.Indicate2D("Punkt wählen", Position)

If (Status = "Cancel") Then
MsgBox "Textmarke wurde nicht eingefügt"
Exit Sub
End If

Dim parameters1 As Parameters
Set parameters1 = drawingDocument1.Parameters

Dim intParam1 As IntParam
Dim ZAEHLER As Single
Dim ZAEHLER_1 As Long
Dim ZAEHLER_10 As Long
Dim ZAEHLER_100 As Long

On Error Resume Next

Set intParam1 = parameters1.Item("ZAEHLER")

If intParam1 Is Nothing Then

    Err.Clear
    Set intParam1 = parameters1.CreateInteger("", 0)
    intParam1.Rename "ZAEHLER"

End If

intParam1.Value = intParam1.Value + 1
ZAEHLER = intParam1.Value

ZAEHLER_100 = Round((ZAEHLER - 50) / 100, 0)

ZAEHLER_10 = Round(((ZAEHLER - 100 * ZAEHLER_100) - 5) / 10, 0)

ZAEHLER_1 = ZAEHLER - (100 * ZAEHLER_100) - (10 * ZAEHLER_10)

On Error GoTo 0

Dim drawingSheets1 As DrawingSheets
Set drawingSheets1 = drawingDocument1.Sheets

Dim drawingSheet1 As DrawingSheet
Set drawingSheet1 = drawingSheets1.ActiveSheet

Dim drawingViews1 As DrawingViews
Set drawingViews1 = drawingSheet1.Views

Dim drawingView1 As DrawingView
Set drawingView1 = drawingViews1.ActiveView

Dim drawingTexts1 As DrawingTexts
Set drawingTexts1 = drawingView1.Texts

Dim drawingText1 As DrawingText

Dim Textbezeichnung As String
Dim Textinhalt As String

Textbezeichnung = "Label." & ZAEHLER

Set drawingText1 = drawingTexts1.Add(Textbezeichnung, Position(0), Position(1))

If ZAEHLER > 99 Then

    drawingText1.Text = Chr(48 + ZAEHLER_100) & Chr(48 + ZAEHLER_10) & Chr(48 + ZAEHLER_1)

ElseIf ZAEHLER > 9 Then

    drawingText1.Text = Chr(48 + ZAEHLER_10) & Chr(48 + ZAEHLER_1)

Else

    drawingText1.Text = Chr(48 + ZAEHLER_1)

End If

End Sub

Du müsstest den Text in einem Editor reinkopieren und das Ganze mit der Extension .CATScript anstelle .txt sichern.

Dann kannst du mit einem Doppelklick im Explorer das Makro bei laufendem CATIA und geöffneter Zeichnung starten.

Nach dem Start eine beliebige Stelle auf der Zeichnung anklicken, die Nummer wird hochgezählt. Ein Parameter, den das Makro zu Beginn einfügt wird hochgezählt. Den könntest du auch wieder im Drawing-Baum doppelklicken und überschreiben, falls du dich mal vertan hast.

Viel Spass damit.

------------------
Grüße aus dem Thurgau
Thomas

+++++++++++++++++++++++++++++++++

CATIA - eine Laune der Natur ...

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke werde ich heute mal ausprobieren...

Vielen dank für die Mühe

Gruß
Micha

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Thomas,

habe das Makro mal getestet.

Es funktioniert so weit.
Es sollte nur so sein das ich das Makro nur einmal starten muß und dann sollte beim ersten Klick die Zahl 1 ausgegeben werden....dann beim nächsten Klick die Zahl 2..usw.

Das ganze sollte Blatt übergreifend gehen.

Sollte das blattübergreifende nicht gehen...wäre es schön wenn ich beim zweiten Blatt die Zahl manuell eingeben könnte mit der man beginnen will.

Wenn ich auf Blatt1 mit der Zahl 5 aufgehört habe sollte es auf Blatt2 mit der Zahl 6 weitergehen.

Hoffe ich habe mich verständlich ausgedrückt.

Das was mir vorschwebt gibt es in der Funtion Ballon....nur eben leider mit dem Leader.

Gruß
Micha

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Das was du willst (Makro bleibt aktiv) ist nicht so einfach.
Dann leg dir das Makro einfach auf eine Tastenkombination dann kannst du die Zahlen schnell erstellen (das hochzählen klappt ja)

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke für den Tipp....nur so mache ich das im Prinzip jetzt auch nur mit der Text Funktion.

Gruß Micha

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Sub CATMain()

Dim ZAEHLER As integer
Dim Status
Dim Position(1)
Dim drawingTexts1 As DrawingTexts
Dim drawingText1 As DrawingText
Dim Textbezeichnung As String

set drawingtexts1 = catia.activedocument.sheets.activesheet.views.activeview.texts
zaehler = inputbox ("Anfangs Nr :")

do 

'  CATIA.ActiveWindow.ActiveViewer.Reframe  'Fit in Page
Status = CATIA.ActiveDocument.Indicate2D("Punkt wählen (Abbr. mit ESC)", Position)
If (Status = "Cancel") Then
MsgBox "Abgebrochen"
Exit Sub
End If

On Error Resume Next

Textbezeichnung = "Label." & ZAEHLER
Set drawingText1 = drawingTexts1.Add(Textbezeichnung, Position(0), Position(1))
drawingText1.Text = zaehler

zaehler = zaehler+1
loop

End Sub

Ein Kollege von mir hat das mal geschrieben....wußte nicht das er das kann....ich bin mit dem Ergebiss zufrieden.
Ist aufs wesentliche reduziert.

Danke für die Antworten und die Mühe.

Gruß Micha 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP