---

Hallo Leute,
Ich hab ein absolut gravierendes Problem in meiner Arbeit entdeckt. Ich füge über ein Makro ein User Defined Feature in mein Catpart ein. Soweit klappt das auch wunderbar. Wenn ich nun aber versuche das Bauteil zu speichern dann verschwindet meine Benutzerkomponente einfach. Wenn ich aber über den regulären Weg mein UDF einfüge, dann klappt das einwandfrei. Weiß jemand was da los ist?. Code ist folgender für mein Makro:

Sub CATMain()

'Aktuelles Dokument festlegen----------------------------------------------------------------------------------------------------
Dim DemonstratorDocument As PartDocument
Set DemonstratorDocument = CATIA.ActiveDocument
Dim Demonstrator As Part
Set Demonstrator = DemonstratorDocument.Part

'Factory instantiieren-----------------------------------------------------------------------------------------------------------

Dim factory As InstanceFactory
Set factory = Demonstrator.GetCustomerFactory("InstanceFactory")
factory.BeginInstanceFactory "HFE_Ring", "C:\Users\BAAB42~1\Catia\Vorlagen Bachelorarbeit\CAD_Vorlagen\HFE_Ring_UDF1.CATPart"
factory.BeginInstantiate

'Inputs setzten------------------------------------------------------------------------------------------------------------------

Dim Ebene As Object
Set Ebene = Demonstrator.FindObjectByName("xy-Ebene")
Dim Punkt As Object
Set Punkt = Demonstrator.FindObjectByName("Referenzpunkt")

factory.PutInputData "xy-Ebene", Ebene
factory.PutInputData "Punkt.1", Punkt

'Instantiieren der referenzierten Benutzerkomponente-----------------------------------------------------------------------------

Dim Instance As ShapeInstance
Set Instance = factory.Instantiate

factory.EndInstanceFactory

'Vernetzten des Referenzpunktes und des Parameters des Haupformelements über eine Formel-----------------------------------------
Dim relations1 As Relations
Dim parameters1 As Parameters
Dim PunktY As Parameter
Dim Formula1 As Formula

Set relations1 = Demonstrator.Relations
Set parameters1 = Demonstrator.Parameters

Set PunktY = parameters1.Item("Demonstrator\Referenzpunkte\Referenzpunkt\Y")
Set Formula1 = relations1.CreateFormula("Formel.1", "", PunktY, "0.5 * `Hauptkörper\HFE_Ring.1\Außendurchmesser`")
Demonstrator.Update

End Sub

Vielen Dank schon mal für eure Hilfe.
Mfg, donbastiano

------------------
bau den sofa grade

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Kannst du das Part mit dem UDF mal hochladen?

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Beispiel_UDF.CATPart

Hier ist eines der Parts mit UDF, die ich verwende. Allerdings vermute ich den Fehler eher in dem Makro für das Einfügen, weil ich ohne Probleme speichern kann, wenn ich die UDFs händisch einfüge

mfg, donbastiano

------------------
bau den sofa grade

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Ohne es getestet zu haben (Vergleich mit anderen Beträgen):
fehlt da noch ein factory.EndInstantiate vor dem factory.EndInstanceFactory ?

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

[Diese Nachricht wurde von bgrittmann am 11. Mrz. 2011 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

ALTER SCHWEDE !!!!!!!!!!!!!!!!!!!!!!!!!!!!!
Bist du gut.... Tausend Dank dir.
Wie so eine elendige Kleinigkeit halt wirklich dafür verantwortlich ist, dass des ganze Programm spackt.
Ich dachte schon ich muss nach nem anderen Weg suchen um meine Einzelkörper aufzubauen.

Vielen vielen Dank

mfg, donbastiano

------------------
bau den sofa grade

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP