---

Hallo,

ich habe mit dem Makrorecorder folgendes aufgenommen:

Set angle2 = parameters2.Item("PART1\AxisSystem.3\EulerAngle2")

Kurz davor im Quellcode werden Koordinatensysteme erstellt.
Wie kann ich dies umgehen, wenn ich sozusagen zur Drehung meiner Koordinatensysteme, alle Koordinatensysteme auswähle und nicht explizit 1 bestimmtes?

---

Hallo newCADuser,

also entweder Alle Achsen unter dem RootAchsen Knoten ansprechen:

Sub CatMainRootAchsen()

Dim MyDocument      As PartDocument
Dim MyPart          As Part
Dim MyAxisSystems  As AxisSystems
Dim MyAxisSystem    As AxisSystem

Set MyDocument = CATIA.ActiveDocument
Set MyPart = MyDocument.Part
Set MyAxisSystems = MyPart.AxisSystems

'Schleife über alle AxisSystems die unter dem Knoten AxisSystems stecken
For Each MyAxisSystem In MyAxisSystems
   
    'mach was mit den Achsen

Next

End Sub

oder mit search über eine Selection:

Sub CatMainSelection()

Dim MyDocument      As PartDocument
Dim MySelection    As Selection
Dim MyAxisSystem    As AxisSystem
Dim i              As Integer

Set MyDocument = CATIA.ActiveDocument
Set MySelection = MyDocument.Selection

MySelection.Clear
MySelection.Search "(CATPrtSearch.AxisSystem),all"

'Schleife über alle AxisSystems die gefunden wurden
For i = 1 To MySelection.Count2
    Set MyAxisSystem = MySelection.Item2(i).Value
   
    'mach was mit den Achsen
    Debug.Print MyAxisSystem.Name
Next

MySelection.Clear

End Sub

oder evtl. anstatt search mit einer UserSelection. (Wenn nur bestimmte Achsen ausgewählt werden sollen)

mfg
Mario

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Mario,

danke für deinen Hinweis. Konnte deinen Tip erfolgreich in mein Makro einbinden.
10 Unities von mir.

Gruß