---

Hallo zusammen,

wie kann ich alle Formulare und Module automatisiert exportieren? Ein Beispiel für Word habe ich hier gefunden: http://www.chf-online.de/vba/vbaexportmakros.htm

Vielen Dank

Georg

[Diese Nachricht wurde von GeorgK am 01. Jul. 2010 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Das Beispeil sieht gut aus und sollte auch funktionieren.
Hast Du es schon ausprobiert?

Generell ist der CATVBA-Editor nichts anderes als der VBA-Editor aus Word und Excel. Was dort geht, geht eigentlich auch im CATVBA.

------------------
Mit freundlichen Grüßen,
Henry Schneider
alias Lila

Es gibt einen ewigen Wettkampf zwischen der Natur und den Ingenieuren:
Die Ingenieure versuchen, immer idioten-sicherere Systeme zu bauen,
die Natur versucht, immer bessere Idioten zu bauen

Xing

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Leider ist es bei mir nicht gelaufen. Habe es mit V5R19Sp3 versucht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Den Hinweis:

Zitat:

---

Wichtig:
Damit auf die Projekte und Module zugegriffen werden kann, muss in der IDE ein Verweis (Extras/Verweise) auf die
Microsoft Visual Basic for Applications Extensibility 5.3

gesetzt sein!

---

hast du beachten? (ich hab es nicht getestet)

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Bernd,

die Verweise habe ich gesetzt.

Viele Grüße

Georg

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Es wäre eine Hilfe gewesen, wenn Du uns die Fehlermeldung genannt hättest.

VBE.VBProjects funktioniert nicht, da das Application-Object CATIA ist.

Eine Lösung dafür habe ich auf die Schnelle leider nicht. 

------------------
Mit freundlichen Grüßen,
Henry Schneider
alias Lila

Es gibt einen ewigen Wettkampf zwischen der Natur und den Ingenieuren:
Die Ingenieure versuchen, immer idioten-sicherere Systeme zu bauen,
die Natur versucht, immer bessere Idioten zu bauen

Xing

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Mit einer Ergänzung aus diesem Beitrag läuft bei mir der Export durch.
Die Abfrage des Zielordners muss noch angpasst werden.

Code:

---

' Damit auf die Projekte und Module zugegriffen werden kann,
' muss in der IDE ein Verweis (Extras/Verweise) auf die
' "Microsoft Visual Basic for Applications Extensibility 5.3"
' gesetzt sein!

Sub ExportMacros()
Dim myComponent As VBComponent
Dim oAPC As New MSAPC.Apc
Dim myProject As VBIDE.VBProject
Dim strFile() As String
Dim strOrdner As String
Dim strNames As String
Dim strProj As String, strProjOrdner As String
Dim strMSG As String
' Ordner auswählen
strOrdner = "C:"
'strOrdner = GetFolderInternal("Ordner auswählen", "C:\")
' Alle Projekte durchlaufen

For Each myProject In oAPC.VBE.VBProjects
' Nur ungeschützte berücksichtigen
If myProject.Protection = vbext_pp_none Then
  On Error Resume Next
  If myProject.VBComponents.Count > 1 Then
    strFile() = Split(myProject.filename, "\")
    strNames = strFile(UBound(strFile()))
    strNames = Replace(strNames, ".dot", "")
    If Len(Dir(strOrdner & "\" & strNames, vbDirectory)) = 0 Then
      MkDir strOrdner & "\" & strNames
    End If
    strProjOrdner = strOrdner & "\" & strNames
    On Error GoTo 0
    ' Alle Module durchlaufen
    strProj = ""
    For Each myComponent In myProject.VBComponents
      With myComponent
      strProj = strProj & .name & vbCr
      ' Modul-Typ ermitteln und mit richtiger Endung exportieren
      If .Type = vbext_ct_StdModule Then
        .Export strOrdner & "\" & strNames & "\" & .name & ".bas"
      ElseIf .Type = vbext_ct_ClassModule Then
        .Export strOrdner & "\" & strNames & "\" & .name & ".cls"
      ElseIf .Type = vbext_ct_MSForm Then
        .Export strOrdner & "\" & strNames & "\" & .name & ".frm"
      ElseIf .Type = vbext_ct_Document Then
        .Export strOrdner & "\" & strNames & "\" & .name & ".cls"
      End If
      End With
    Next myComponent
    strMSG = strMSG & strProjOrdner & ":" & vbCrLf & strProj & vbCrLf
  End If
End If
Next myProject
MsgBox "Es wurden alle Module aus folgenden Vorlagen exportiert: " & vbCrLf & strMSG, _
  vbInformation, "Module exportieren"
End Sub

---

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Bernd,

herzlichen Dank.
Ich hatte es schon aufgegeben.
Noch ein kleiner Hinweis: unter 64bit Windows 7 und 32bit CATIA R19 habe ich zusätzlich noch 'Microsoft APC 6.2 Object Library' als Verweis setzen müssen.

Gruß,
Zoltan

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Bernd und Zoltan,

vielen Dank für Eure Hilfe.

Viele Grüße

Georg

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo zusammen,

ich habe die Hinweise aus diesem Beitrag umgesetzt, sprich den Code von bgrittmann und in der VBA-IDE folgende Referenzen geladen:

"Microsoft Visual Basic for Applications Extensibility 5.3"
"Microsoft APC 6.2 Object Library"

Leider erhalte ich die Meldung:

Run-time error '429':

ActiveX component can't create object

Ich habe hier allerdings ein VBA 7.1 mit Catia V5 R24. Weiß jemand, ob das damit noch funktioniert?

Danke für jeden Hinweis.

Gruß, Picard

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Picard,

Zitat:

---

Original erstellt von picard:

Run-time error '429':

ActiveX component can't create object

Ich habe hier allerdings ein VBA 7.1 mit Catia V5 R24.
Weiß jemand, ob das damit noch funktioniert?

---

ich hab zwar VBA7 nicht; trotzdem denke ich wäre zunächst interessant
zu wissen welches Object nicht erzeugt werden kann.

Wo tritt der Fehler auf?

Tschau,
Joe

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo joehz,

es war das APC Objekt (MSAPC.Apc), bei dem der Fehler auftrat.

Es sieht so aus, als wäre hier einfach ein Versionskonflikt. Ich habe nun statt:

Microsoft APC 6.2 Object Library

die

Microsoft APC 7.1 Object Library

Verlinkt. Damit wird zumindest das APC Objekt erstellt. Der Code scheint zu laufen.

Danke für alle Hinweise, die haben mir wieder mal gut weiter geholfen.

Gruß, Picard

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ich habe noch eine Seite gefunden, auf der viele Hinweise und Beispiele rund um die Automatisierung des VBA-Editors enthält:

http://www.cpearson.com/excel/vbe.aspx

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP