---

Hallo,

Ich habe eine Function geschrieben (VBA-Projekt): der User soll ein Objekt selektieren und ich suche das Part, wo das Objekt sich befindet.

Um das Part zu finden, navigiere ich in der Struktur mit der Methode ".parent" (Schleife Do...Loop Until) bis ich ein Objekt "PartDocument" finde.

Code:

---

Sub CATMain()
    Dim oDoc As Document
    Dim cSel
    Dim oPart As Part
    Dim Status As String
    Dim InputObjectType(0)
   
    Set oDoc = CATIA.ActiveDocument
    Set cSel = oDoc.Selection
   
    cSel.Clear
    InputObjectType(0) = "AnyObject"
    Status = cSel.SelectElement2(InputObjectType, "Select a Point. Press ESC to end the selection.", True)
   
    FindPartFromObject cSel.Item(1).Value, oPart
   
End Sub

Function FindPartFromObject(oObject As AnyObject, oPart As Part) As Boolean
    Dim i As Integer
    Dim oParent As AnyObject
    i = 1
    Set oParent = oObject
    Do
        Debug.Print oParent.Name & ", " & TypeName(oParent)
        On Error Resume Next
        Set oParent = oParent.Parent
        If Err.Number <> 0 Then
            MsgBox "Error: Parent method fail for the object " & oParent.Name & ".", vbCritical, "Error: Parent method failed"
            On Error GoTo 0
            FindPartFromObject = False
            Exit Function
        End If
        i = i + 1
    Loop Until TypeName(oParent) = "PartDocument" Or i = 30
    If TypeName(oParent) <> "PartDocument" Then
        MsgBox "Part not found"
        FindPartFromObject = False
    Else
        On Error Resume Next
        Set oPart = oParent.Part
        If Err.Number <> 0 Then
            MsgBox "Error: Part method fail for the object " & oParent.Name & ".", vbCritical, "Error: Part method failed"
            On Error GoTo 0
            FindPartFromObject = False
            Exit Function
        End If
        Debug.Print "Partnumber: " & oPart.Name
        FindPartFromObject = True
    End If
End Function

---

Es funktionniert für viele Objekte einwandfrei.
Aber, sobald ich einen Geometrical Set in einem Body habe funktionniert das ".Parent" nicht mehr. Das Makro navigiert bis diesen Geometrical Set und meldet dann, daß die method ".parent" für diesen Objekt nicht geklappt hat.

Hat jemand eine Erklärung ?
Alternativ, hat jemand eine Lösung um das Object Part auch im Produktkontext aus ein beliebiges Objekt zu finden ?

Gruß,
Florent.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Florent,

das geht am einfachsten mit der Methode FindObject:

Code:

---

Set obj = cSel.FindObject("CATIAPart") 'Part
Set obj = cSel.FindObject("CATIAProduct")'Instanz

---

Gruß
CAMiCADse

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

Danke für den Vorschlag.
Nach ein Paar Versuche scheint es, genau zu tun, was ich wollte.
Nochmal Danke.

[Diese Nachricht wurde von ptit.tom am 24. Jun. 2009 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP