---

Guten Tag,

eine ausgiebige Forensuche hat mich leider nicht weiter gebracht, darum poste ich meine Frage in einem neuen Thread. Kurz: Gibt es eine Möglichkeit, Geometrie aus einer .stp- pder .igs-Datei in ein *bestehendes* Part zu importieren?

Die zunächst naheliegende Möglichkeit über die Open-Methode

Code:

---

Set doc = CATIA.Documents.Open("geometry.stp")

---

liest die Datei korrekt ein, dabei wird allerdings in CATIA ein neues Part erzeugt was ich gerne vermeiden möchte. Die Geometrie soll direkt in ein bestehendes Geometrisches Set eines bestehenden Parts importiert werden. Hat jemand eine Idee?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Versuch mal folgendes:
Das Dokument in welches das Stepfile eingefügt werden soll öffnen.
Den Pfad "C:\STEPFILE.stp" abändern.

Code:

---

Sub CATMain()
   
    Dim documentDest As PartDocument
    Set documentDest = CATIA.ActiveDocument
   
    Dim documents1 As Documents
    Set documents1 = CATIA.Documents
   
    Dim documentSour As Document
    Set documentSour = documents1.Open("C:\STEPFILE.stp")

    Dim Sel As Selection
    Set Sel = CATIA.ActiveDocument.Selection
    Sel.Search "Name=*"
    For i = 1 To Sel.Count
        If TypeName(Sel.Item(i).Value) = "Solid" Then
            Set Obj = Sel.Item(i).Value
            Exit For
        End If
    Next
   
    Sel.Clear
    Sel.Add Obj
    Sel.Copy

    documentDest.Activate
   
    Dim SelDest As Selection
    Set SelDest = documentDest.Selection
   
    Dim part1 As Part
    Set part1 = documentDest.Part
   
    Dim body1 As Body
    Set body1 = part1.Bodies.Add()

    part1.Update
   
    SelDest.Add body1
    SelDest.Paste
   
    SelDest.Clear
   
    documentSour.Close

End Sub

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

@apollo11: Ok, also ein Copy/Paste über ein temporäres Dokument. Das wollte ich zunächst eigentlich vermeiden, aber anscheinend geht es "direkt" wohl nur über CAA. Ich habe mal Dein Programm für meine Zwecke etwas abgeändert, und es funktioniert recht gut. Man merkt vom Anlegen des temporären Dokuments tatsächlich kaum etwas. Vielen Dank für Deine Anregung!

(Wen es interessiert: Hier meine Version, bei der ich mir zunutze mache daß die STP-Geometrie beim Einlesen anscheinend immer in einem Geometrischen Set abgelegt wird. Dieses wird kopiert und in das aktuelle Part eingefügt. Geht bestimmt noch besser/sicherer, ich bin noch Anfänger auf dem Gebiet)

Code:

---

Sub CATMain()
 
    Dim documentDest As PartDocument
    Set documentDest = CATIA.ActiveDocument
 
    Dim documents1 As Documents
    Set documents1 = CATIA.Documents
 
    ' Lies temporäres Dokument
    Dim documentSour As Document
    Set documentSour = documents1.Open("C:\STEPFILE.stp")

    ' Copy Geometrisches Set aus temporärem Dokument
    Dim Sel As Selection
    Set Sel = CATIA.ActiveDocument.Selection
    Sel.Search "Name=Geometrisches Set*"
    Sel.Copy

    ' Re-Switch auf eigentliches Dokument
    documentDest.Activate
 
    ' Paste in aktuelles Dokument (muss ein Part sein)
    Dim SelDest As Selection
    Set SelDest = documentDest.Selection
    SelDest.Search "Name=*Part*"
    SelDest.Paste
    SelDest.Clear
 
    documentSour.Close

End Sub

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus

Handelt es sich bei deinen STEP-Modellen um Flächenmodelle?
Vorsicht bei Volumen-Modellen wir dieses nicht im "geometrischen Set" abgelegt (nur so als Hinweis für die Zukunft bzw. Volumen).

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

@Bernd: Danke für den Hinweis. Gegenwärtig handelt es sich tatsächlich nur um Flächenmodelle.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP