---

Hallo zusammen!

Ich steh vor dem Problem, dass ich eine vorhandene Loft bearbeiten möchte. Und zwar möchte ich ihr Führungselemente hinzufügen.

Das Problem ist, dass ich den Befehl um eine vorh. Loft zu bearbeiten nicht kenne. Daher wird mir bis jetzt eine 2. Loft generiert.

Kann mir einer weiterhelfen?

  - Jürgen

So sieht mein Quellcode dafür bis jetzt aus:

Sub Wing_Fuehrungselemente()
Dim iProfilzahl As Integer

Dim partDocument1 As Object
Dim part1 As Object
Dim hybridShapeFactory1 As Object
Dim hybridShapeLoft1 As Object
Dim hybridBodies1 As Object
Dim hybridBody1 As Object
Dim hybridShapes1 As Object

Dim GuideSpline As Object
Dim reference As Object
Dim SectionSpline As Object
   
iProfilzahl = 12

'Get CATIA
Set partDocument1 = GetCATIAPartDocument

'Get part
Set part1 = partDocument1.Part

Set hybridShapeFactory1 = part1.HybridShapeFactory

Set hybridShapeLoft1 = hybridShapeFactory1.AddNewLoft() |<--- Hier liegt denke ich das Problem

hybridShapeLoft1.SectionCoupling = 1

hybridShapeLoft1.Relimitation = 1

Set hybridBodies1 = part1.HybridBodies

Set hybridBody1 = hybridBodies1.Item("GeometryFromExcel")

Set hybridShapes1 = hybridBody1.HybridShapes

'Add Guides

For i = 1 To 3 Step 1
   
    Set GuideSpline = hybridShapes1.Item("Spline." & iProfilzahl + i)
    Set reference = part1.CreateReferenceFromObject(GuideSpline)

    hybridShapeLoft1.AddGuide reference
   
Next

'Add Sections

For i = 1 To iProfilzahl Step 1
    Set SectionSpline = hybridShapes1.Item("Spline." & i)
    Set reference = part1.CreateReferenceFromObject(SectionSpline)

    hybridShapeLoft1.AddSectionToLoft reference, 1, Nothing
Next

hybridBody1.AppendHybridShape hybridShapeLoft1

part1.InWorkObject = hybridShapeLoft1

part1.Update

End Sub

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo JuergenHeckmann,

eigentlich hast du das Zugriff-Prinzip schon mehrfach in Deinem(?) Script verwendet.

Ohne es getestet zu haben, schlage ich mal folgendes vor:

Code:

---

'Set hybridShapeFactory1 = part1.HybridShapeFactory - wird nur zur Erzeugung gebraucht!
Set hybridBodies1 = part1.HybridBodies
Set hybridBody1 = hybridBodies1.Item("Body_vom_Loft")
Set hybridShapes1 = hybridBody1.HybridShapes
Set hybridShapeLoft1 = hybridShapes1.Item("Loftname")

---

Dann müsste das zu ändernde Loft gewählt sein und kann bearbeitet werden. ODER?

mfg,
Lusilnie

------------------

Alle Aussagen zu DassaultSystemes-Produkten sind sehr optimistisch, selbst diese!!!

frei nach größeren Geistern

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Dank für die Antwort!

Hat ohne Probleme funktioniert! :-)

- Jürgen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP