---

Hallo zusammen,

ich hab ein Problem mit selection1.cut und selection1.PasteSpecial "CATSpecBreakLink"

Wenn ich anstatt cut copy einsetze funktioniert es. Bei cut kommt es mir so vor, als ob es gar nicht in den Zwischenspeicher geschrieben wird. Hat mit da jemand eine Lösung? Ich arbeite mit V5R12SP3 unter Windows

hier noch mein Programm:

Sub CATMain()

Dim selection1 As Selection
Set selection1 = CATIA.ActiveDocument.Selection
selection1.Clear

selection1.Search "Name=*uct2*,all"        ' Unterproduct selektieren, in dem die Bauteile drin sind

selection1.Search "(Name=*DECK*);sel" 'Bauteile selektieren

selection1.Copy ' selektierte Bauteile ausschneiden
selection1.Clear

selection1.Search "Name=*uct4*,all" ' Unterproduct  selektieren, in dieses Unterproduct sollen die Bauteile eingefügt werden

selection1.PasteSpecial "CATSpecBreakLink" 'Bauteile einfügen (aus Zwischenspeicher)

End Sub

Vielen Dank für eure Hilfe
hasim

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

zum Einen gibt es hier einen interessanten Thread zu dem Thema: http://ww3.cad.de/foren/ubb/Forum137/HTML/000237.shtml

Ansonsten denke ich, dass du vor dem PasteSpecial noch ein Add einbauen musst, damit es auch irgendwo eingefügt werden kann.

Viele Grüße

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo PI,

danke für deine Antwort das mit Add habe ich auch schon ausprobiert funktioniert auch nicht.

Mein Test war gerade noch, das Makro bis einschliesslich selection1.cut laufen zu lassen und dann manuell über pastespecial/break link die Bauteile einzufügen, ging aber auch  nicht. Mit selction1.copy funktioniert es. Hab jetzt mein Macro auch auf copy umgeschrieben und lösche dann halt die Bauteile die ich nicht mehr brauche.

Gruß
Hasim

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ich habe eine thematisch ähnliche Frage:

Was möchte ich:
Ich möchte ein symmetrisches Einzelteil per Makro erzeugen lassen.

Was soll dabei gemacht werden:

Die FETT markierten Punkte habe ich noch nicht hinbekommen  (Punkt 3, 6 und 7)

1. publizierten PartBody des geöffneten Originalteils kopieren
2. neues Part erzeugen
3. aus der Zwischenablage mit Paste Special - As Result with Link einfügen
4. eingefügten Body mit Solid als PartBody setzen (da kein HybridDesign)
5. den nun obsoleten leeren Body löschen
6. das Symmetry-Feature anwählen
7. nach der vom Anwender zu selektiereneden Spiegelebene fragen
8. PartBody als Define in Work Object setzen
9. Publizierungen vornehmen

Was habe ich bereits:

Code:

---

Language="VBSCRIPT"

Sub CATMain()

'Kopieren des Original PartBody
'--------------------------

Set documents1 = CATIA.Documents

Set partDocument1 = CATIA.ActiveDocument
Set selection1 = partDocument1.Selection
selection1.Clear
selection1.Search "(Name=*PartBody* & CATPrtSearch.BodyFeature),all"
selection1.Copy

'Erzeugen eines neuen Parts
'--------------------------

Set partDocument1 = documents1.Add("Part")

'Einfuegen des kopierten Bodies As Result With Link
'--------------------------

Set partDocument2= CATIA.ActiveDocument
Set selection2 = CATIA.ActiveDocument.selection
Set part2 = partDocument2.Part
Set selection2 = partDocument2.selection
selection2.Add part2
selection2.PasteSpecial "CATPrtAsResult"
part2.Update

'Kopierten Body als PartBody setzen
'--------------------------

Set partDocument1 = CATIA.ActiveDocument
Set part1 = partDocument1.Part
Set bodies1 = part1.Bodies
Set body2 = bodies1.Item("PartBody")
part1.MainBody = body2

'Symmetry anlegen
'--------------------------

'neuer PartBody in Work
'--------------------------

part1.InWorkObject = body2
part1.Update

'Publizierung wird gesetzt
'--------------------------

Set partDocument1 = CATIA.ActiveDocument
Set product1 = partDocument1.GetItem(fileName)
Set reference1 = product1.CreateReferenceFromName(fileName&"/!xy plane")
Set publications1 = product1.Publications
Set publication1 = publications1.Add("xy plane")
publications1.SetDirect "xy plane", reference1

Set reference2 = product1.CreateReferenceFromName(fileName&"/!yz plane")
Set publication2 = publications1.Add("yz plane")
publications1.SetDirect "yz plane", reference2

Set reference3 = product1.CreateReferenceFromName(fileName&"/!zx plane")
Set publication3 = publications1.Add("zx plane")
publications1.SetDirect "zx plane", reference3

Set reference4 = product1.CreateReferenceFromName(fileName&"/!Absolute Axis System")
Set publication4 = publications1.Add("Absolute Axis System")
publications1.SetDirect "Absolute Axis System", reference4

Set reference5 = product1.CreateReferenceFromName(fileName&"/!PartBody")
Set publication5 = publications1.Add("PartBody")
publications1.SetDirect "PartBody", reference5

'leeren Body löschen
'--------------------------

Set oDoc = CATIA.ActiveDocument
Set oPart = oDoc.Part
Set oSel = oDoc.Selection

oSel.clear
for x = oPart.bodies.count to 1 step -1
  Set oBody = oPart.bodies.item(x)
  if oBody.shapes.count =0 then
        oSel.add oBody
        oSel.delete
        oSel.clear
  end if
next

'Elemente abwaehlen
'---------------------

Set oSel = CATIA.ActiveDocument.Selection
oSel.Clear
CATIA.StartCommand "Fit All In"
CATIA.RefreshDisplay = True

End Sub

---

Ich bin für jede Hilfe sehr dankbar!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Code:

---

Language="VBSCRIPT"

Sub CATMain()

'Kopieren des Original PartBody
Set documents1 = CATIA.Documents

Set partDocument1 = CATIA.ActiveDocument
Set selection1 = partDocument1.Selection
selection1.Clear
selection1.Search "(Name=*PartBody* & CATPrtSearch.BodyFeature),all"
selection1.Copy

'Erzeugen eines neuen Parts
'--------------------------

Set partDocument1 = documents1.Add("Part")

---

Aus der Doku:

Example:
The following example creates a PartDocument document in the collection retrieved in PartDoc.
Dim PartDoc As Document
Set PartDoc = Documents.Add("Part")

Müsste das dann nicht bei Dir heissen:

[CODE]
Set partDocument2 = documents1.Add("Part")

---

Sonst deklarierst den PartDoc1 zwei mal.

Dann kannst Dir auch weiter unter

Zitat:

---

'Einfuegen des kopierten Bodies As Result With Link
'--------------------------
Set partDocument2= CATIA.ActiveDocument

---

sparen.

Tschau,
Joe

------------------
Inoffizielle Catia Hilfeseite

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Einige weiter Verbesserungsvorschläge:
- nicht über den Namen auf den neu eingefügten Körper zugreifen sondern über den Zähler
- bei "PasteSpecial" hattest du dich verschrieben
- besser sprechende Variablennamen verwenden
- zum Spiegel sollte die Methode "AddNewSymmetry2" gehen
Anbei ein etwas angepasster Code (die Veröffentlichungen hab ich mal entfernt, für was benötigst du die?)

Code:

---

Language="VBSCRIPT"

Sub CATMain()

'Kopieren des Original PartBody
'--------------------------

Set documents1 = CATIA.Documents

Set SourcePartDocument = CATIA.ActiveDocument
Set SourceSelection = SourcePartDocument.Selection
SourceSelection.Clear
SourceSelection.Add SourcePartDocument.part.mainbody
SourceSelection.Copy

'Erzeugen eines neuen Parts
'--------------------------

Set TartgetPartDocument = documents1.Add("Part")

'Einfuegen des kopierten Bodies As Result With Link
'--------------------------

Set TargetSelection = TartgetPartDocument.selection
Set TargetPart = TartgetPartDocument.Part
TargetSelection.clear
TargetSelection.Add TargetPart
TargetSelection.PasteSpecial "CATPrtResult"
TargetPart.Update

'Kopierten Body als PartBody setzen
'--------------------------

Set bodies1 = TargetPart.Bodies
Set body2 = bodies1.Item(bodies1.count)
TargetPart.MainBody = body2

'Symmetry anlegen
'--------------------------

'neuer PartBody in Work
'--------------------------

TargetPart.InWorkObject = body2
TargetPart.Update

'leeren Body löschen
'--------------------------

TargetSelection.clear
for x = TargetPart.bodies.count to 1 step -1
  Set oBody = TargetPart.bodies.item(x)
  if oBody.shapes.count =0 then
        TargetSelection.add oBody
        TargetSelection.delete
        TargetSelection.clear
  end if
next

'Elemente abwaehlen
'---------------------

TargetSelection.Clear
CATIA.StartCommand "Fit All In"
CATIA.RefreshDisplay = True

End Sub

---

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Dank für eure schnellen Antworten!

Die Methodik für Symmetry werde ich mir anschauen! Legen wir das zur Seite 
Die Publizierung wird lediglich für den Q-Checker benötigt, der meckert sonst meine Teile aus.
Aber die Publizierung kann ich selbst einfügen, das Codeschnipsel dafür funktioniert ja prinzipiell.

Ich habe Bernds Code eingepflegt.
Das Skript stoppt leider jetzt bei der Erzeugung des neuen Parts. Ich nehme an, es handelt sich dabei um einen Tippfehler?

Code:

---

'Erzeugen eines neuen Parts
'---------------------------------------------------------------------------------------------
Set TartgetPartDocument = documents1.Add("Part")

---

Ich habe diesen mal korrigiert. Kam noch in weiteren Passagen vor, ich nehme an, das kommt von der STRG-H Funktion. Falls ich damit falsch liege, bitte korrigiert mich! Leider stoppt das Skript immer noch an exakt dieser Stelle.

Danke und Grüße

Steve

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Da es überall gleich falsch geschrieben ist, dürfte das nicht das Problem sein.
Bei mir läuft der Code. Hast du ggf die Zeile "Set documents1 = CATIA.Documents" geändert/gelöscht?

Gruß
Bernd

PS: Manchmal hilft auch die Fehlermeldung zu lesen.

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Genau das war es!

Mal wieder den Wald vor lauter Bäumen nicht gesehen.
Was für ein absoluter Anfängerfehler.
Tut mir Leid!

Vielen Dank für deine Hilfe!

Vielleicht werde ich diese später für die Symmetry nochmals benötigen 

Steve

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP