---

Hallo zusammen,

ich suche eine Möglichkeit in meinem VBA Programm einen String in mehrere Single zu zerlegen:

Beispiel String: "Ro ø25x3,5*395 fix"

herauskommen soll

Single1 = 25

Single2 = 3,5

Single3 = 395

Ich kriegs einfach nicht hin. Bitte helft mir.

Oder wenigstens wie schmeiße ich alle Buchstaben und Sonderzeichen aus dem String außer x * und ,

Danke im Voraus

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Phillip,

ich habe dir mal ein Bespiel zusammen geschrieben 

Code:

---

Sub CATMain()

    Dim str1 As String
    Dim str2() As String
    Dim str3 As Variant
    Dim i As Integer
   
    str1 = "Ro ø25x3,5*395 fix"
    str2 = GetNumbersSplittedUp(str1)
   
    i = 1
    For Each str3 In str2
        MsgBox ("Wert" & i & ": " & str3)
        i = i + 1
    Next
   
End Sub

Function GetNumbersSplittedUp(strText As String) As String()
   
    Dim i As Integer
    Dim j As Integer
    Dim strTemp As String
    Dim strtemp2 As String
    Dim strRet() As String
   
    j = 0
    For i = 0 To Len(strText)
        strTemp = Mid(strText, i + 1, 1)
        If IsNumeric(strTemp) = True Or strTemp = "," Then
            strtemp2 = strtemp2 & strTemp
        Else
            If Len(strtemp2) > 0 Then
                ReDim Preserve strRet(j)
                strRet(j) = strtemp2
                strtemp2 = ""
                j = j + 1
            End If
        End If
    Next
   
    GetNumbersSplittedUp = strRet
   
End Function

---

------------------
MFG
Rick Schulz

Nettiquette (CAD.de)  -  Was ist die Systeminfo?  -  Wie man Fragen richtig stellt.  -  Unities

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Suuuper! Danke!

Es macht genau das was es soll!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo zusammen

Oder das selbe mit RegEx.

Code:

---

Public Sub RegEx_Test()
    Dim objRegEx As Object, objMatch As Object
    Dim strText As String
    Dim intIndex As Integer
    strText = "Ro ø25x3,5*395 fix"
    Set objRegEx = CreateObject("vbscript.regexp")
    With objRegEx
        .Global = True
        .IgnoreCase = True
        .MultiLine = False
        .Pattern = "[\d,.]+"
        Set objMatch = .Execute(strText)
    End With
    For intIndex = 0 To objMatch.Count - 1
        Debug.Print objMatch(intIndex)
    Next
    Set objRegEx = Nothing
    Set objMatch = Nothing
End Sub

---

Gruss Andreas

------------------
21 ist nur die halbe Antwort.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP