---

Hallo,

ich sitze gerade an meiner Diplomarbeit und betrachte eine runden gekerbten Zugstab. Bei der Berechnung funktioniert alles ohne Probleme, allerdings beim Auslesen der Hauptspannungen in eine Text-Datei sagt er mir, dass keine Daten für die ausgewählten Knoten vorhanden sind. Meine Vermutung ist, dass ich etwas bei der Selektierung der Knoten falsch mache und keine Informationen für den Knoten vorhanden sind, da wenn ich mir die Hauptspannungen im Programm anzeigen lasse, welche vorhanden sind. Zum besseren Verständnis habe ich meinen Code mal angefügt.

/clear
/OUTPUT,2d_Vdf1_Zugstab_mit_Kerbe_5mm,txt
/FILNAME,2d_Vdf1_Zugstab_mit_Kerbe_5mm

!Parameter: (in [mm])!
X1 = 0
Y1 = 25                    !Länge / 2 !
Ra = 13.993/2                      !Radius Stab!
Rk = 5.025                      !Radius im Bereich der Kerbe
Y2 = 0                     
R1 = 5                      !Kerbradius Radius!
R2 = R1+1.5                !Kerbradiusbereich Radius!
m1 = 0.4                    !=> m*Y1 => Gibt an auf welcher Höhe dir Probe geteilt wird!
u_y = 2.5                !Verschiebung in y-Richtung!

PI = 3.141592653589793

radius_k = 20              !Teilung des Kerbradiuses!
kante_k = 7                !Teilung der Kante des Kerbbereichs!
kante_u = 1.2*kante_k      !Teilung der Kante unten!
kante = 1.5*kante_u        !Teilung der Kanten außen - oberer Bereich!

v_kante = 0.4              !Steigerung der Vernetzung

!******************************************
/prep7
!Elementtyp!
ET,1,plane42,,,1               

!Geometrie:!
!Rechteck!   
RECTNG,X1,Ra,Y1,Y2
!Kreis!
CYL4,(Rk+R1),Y2,,,R1
!Abziehen der Volumen von einander!
ASBA,1,2,
!zweiter Kreis um Elemente abzugrenzen!
CYL4,(Rk+R1),Y2,,,R2
!Kreis abgrenzen!
ASBA,3,1,,keep,delete
ASBL,ALL,ALL
!In Bereiche aufteilen!
RECTNG,X1,Ra,Y1,(Y1*m1)
ASBL,ALL,ALL
ADELE,4
NUMMRG,all
!Nummern neu vergeben!
NUMCMP,ALL
!Flächen verkleben!
AGLUE,all

!Unterteilung der Linien!

!Kerbbereich!
!Kerbradius!
LESIZE,8,,,radius_k
LESIZE,9,,,radius_k
!Kante!
LESIZE,6,,,kante_k
LESIZE,11,,,kante_k

!Kanten!
!unten!
LESIZE,6,,,kante_u
!außen!
LESIZE,11,,,kante_u,v_kante

!oberer Bereich!
!außen!
LESIZE,5,,,kante,
!innen!
LESIZE,7,,,kante,

!**************************************

!Material:!
mp,ex,1,(552.5410/0.0024183)            !Eingabe des E-Moduls!
mp,ey,1,(552.5410/0.0024183)
mp,ez,1,(552.5410/0.0024183)
mp,prxy,1,0.3                            !Querdehnzahl!
tb,miso,1,1,17
tbpt,defi,0.002162,494.0576
tbpt,defi,0.0115288,494.0576
tbpt,defi,0.0238472,505.8563
tbpt,defi,0.0278462,507.9625
tbpt,defi,0.0285757,512.7893
tbpt,defi,0.0294808,520.2573
tbpt,defi,0.0314852,529.3775
tbpt,defi,0.0373778,550.2045
tbpt,defi,0.0426919,565.5424
tbpt,defi,0.0470831,577.4260
tbpt,defi,0.0513945,587.6120
tbpt,defi,0.0547619,594.6316
tbpt,defi,0.0640159,610.2575
tbpt,defi,0.0841249,631.7600
tbpt,defi,0.0987053,639.9622
tbpt,defi,0.1154203,644.7057
tbpt,defi,0.1299198,645.7570
tbplot,miso,1

!******************************************
!Vernetzen!

!Übergangsbereich!
!innen!
LESIZE,10,,,1.0*radius_k*0.6,1/(1.0*v_kante)
!oben!
LESIZE,4,,,radius_k*0.4

AMAP,3,1,6,5,9

!Kerbbereich
AMESH,1

!oberer Bereich!
LESIZE,3,,,radius_k*0.4
AMESH,2

FINI
!**********************************************

!LÖSUNG!

/SOLU

!Allgemeines!
antype,static
NLGEOM,ON
AUTOTS,ON
NSUBST,80,,80
PSTRES,ON
OUTRES,all,all

!Festhalterung!
NSEL,S,LOC,Y
D,all,uy
alls

!!Leisteinleitung - Weggesteuert!
nsel,s,loc,y,Y1
D,all,ux
D,all,uy,u_y
ALLS

SOLVE

/Post1

!Spannungen und Dehnungen im Kerbbereich!

*cfopen,Vdf1_Kerbspannungen_Kerbe_5mm,txt
*get,anzsteps,active,0,solu,ncmss
lsel,s,line,,8,,,1
nsll,s,1
*get,anzknot,node,,count
*get,nmin1,node,,num,min
*do,n,1,anzsteps,1
  set,1,n
  nmin=nmin1
  *do,k,1,anzknot,1
    *get,sigma_1,node,nmin,s,1
    *get,sigma_2,node,nmin,s,2
    *get,sigma_3,node,nmin,s,3
    *cfwrite,,n,nmin,sigma_1,sigma_2,sigma_3,plast_vergl_dehnung
    nmin=ndnext(nmin)
  *enddo
*enddo
*cfclos
finish

Ich hoffe mein Problem wird dadurch verständlicher.
Nur noch einmal als Hinweis, mein Problem befindet sich im /Post1

Gruß
Ede

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin,

mit *cfwrite schreibst Du Befehle. Was Du benötigst ist ein *vwrite.
Wichtig: Formatierungen beachten und "*Vwrite" ohne Tabs oder Leerzeichen beim ersten Zeichen der Zeile schreiben.

Hoffe, das hilft fürs Erste. Grüße

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke, ersteinmal für die Antwort, aber das Problem liegt nicht im *cfwrite Befehl, sondern die erste Fehlermeldung kommt bereits beim *get Befehl. Hier sagt er mir:

Requested data is not stored for node ... .                             
  Line= *GET,sigma_1,node,nmin,s,1                                 
  The *GET command is ignored. 

Daher kommt auch meine Vermutung, dass beim Selektieren der Knoten etwas falsch ist.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Also,

1. Laut Hilfe bekommst Du die Spannungen per *get Befehle für die Knoten selektierter Elemente:

Zitat:

---

Entity = NODE, ENTNUM = N (node number) for averaged nodal results based on selected elements

---

Du solltest also die zu den Knoten gehörigen Elemente mit selektieren.

2. Kannst Du Plane42 durch 183 ersetzen (siehe Hilfe)
3. Andere Laufvariablen der *do-Schleifen verwenden als gängige Ansys-Commands

4. Die Anzahl der Substeps liest Du aus, indem Du den letzten Substep eines Lastschrittes setzt.

Dann sollte das ganze in etwa so ausschauen:

Code:

---

/Post1
set,1,last !Loadstep 1, letzter Substep
*get,anzsteps,active,,set,sbst

lsel,s,line,,8,,,1
nsll,s,1
esln,s,0 !Elemente selektieren

*get,anzknot,node,,count
*get,nmin1,node,,num,min

*do,ii,1,anzsteps,1 !irgendwas anderes als n als Variable
  set,1,ii
  nmin=nmin1
  *do,kk,1,anzknot,1          !irgendwas anderes als k
    *get,sigma_1,node,nmin,s,1
    *get,sigma_2,node,nmin,s,2
    *get,sigma_3,node,nmin,s,3
    !*cfwrite,,ii,nmin,sigma_1,sigma_2,sigma_3,plast_vergl_dehnung
    nmin=ndnext(nmin)
  *enddo
*enddo
*cfclos
finish

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Super, danke. Es hat geklappt. Der fehlende Hinweis war, dass ich vergessen habe die Elemente mit zu selektieren. Es funktioniert alles.
Danke vielmals!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP