---

frank.txt

Guten Morgen

Ich versuche verzweifelt die Resultate in ein File zu schreiben mit folgendem Script.

Der Hintergrund ist folgender: An der Stelle wo Koordinatensystem x ist befinden sich zwei Knoten. Ich lese die Resultate der Knoten aus und subtrahiere diese voneinander. Das ganze will ich anschliessend in ein file schreiben.

Das Problem:
Beim schreiben in das File werden mir aus unerklärlichen Gründen pro Koordinatensystem zwei Zeilen geschrieben (file ist im Anhang), warum?

!  Commands inserted into this file will be executed immediately after the Ansys /POST1 command.

!  Active UNIT system in Workbench when this object was created:  Metric (mm, t, N, s, mV, mA)

! Dieses Skript wertet die Verschiebungen aus

!*******************************************************************************************************************

!Makro um die Werte der jeweiligen Knoten bei den Kooridnatensystemen zu ermitteln

*create,test,mac
*del,res
*del,delta

csys,arg1 ! Wählt das Koordinatensystem "Arg1"

nsel,s,loc,x,0 ! Selektiert alle Knoten die die Koordinaten X=0 haben
nsel,r,loc,y,0 ! Reselektiert (von der vorherigen Auswahl) alle Knoten die die Koordinaten Y=0 haben
nsel,r,loc,z,0 ! Reselektiert (von der vorherigen Auswahl) alle Knoten die die Koordinaten Z=0 haben
n1=ndnext(0) ! Gibt die nächste Knotennummer von 0 (von dem selektierten Set) an
n2=ndnext(n1) ! Gibt die nächste Knotennummer von n1 (von dem selektierten Set) an

*dim,res,array,2,4 ! Definiert Variable

*GET,res(1,1),node,n1,u,x ! Verschiebungen am Knoten in Var schreiben
*GET,res(1,2),node,n1,u,y
*GET,res(1,3),node,n1,u,z
*GET,res(1,4),node,n1,u,sum

*GET,res(2,1),node,n2,u,x
*GET,res(2,2),node,n2,u,y
*GET,res(2,3),node,n2,u,z
*GET,res(2,4),node,n2,u,sum

*do,i,1,2,1 ! Umwandlung der Resultate in [um]
*do,j,1,4,1
  res(i,j)=res(i,j)*1000000
*enddo
*enddo

*dim,delta,array,4 ! Berechnet das Delta

*do,i,1,4,1
delta(i)=res(2,i)-res(1,i)
*enddo

/com, delta 1 = %delta(1)%
/com, delta 2 = %delta(2)%
/com, delta 3 = %delta(3)%
/com, delta 4 = %delta(4)%

*cfopen,frank,txt,,append ! öffnet das File auswertung.txt und hängt die Daten weiter an

*vwrite,%arg1%,'  ',delta(1),'  ',delta(2),'  ',delta(3)
(F9.0,a2,F9.4,a2,F9.4,a2,F9.4)

*cfclos

alls
*end ! Ende vom Makro

!*******************************************************************************************************************

!Hier wird das Textfile gelöscht und die Überschriften erzeugt

*cfopen,frank,txt
*vwrite,'Werte',' in ','[um]'
(a5,a4,a4)
*vwrite,'Koord-sys','  ','dx','  ','dy','  ','dz'
(a9,a2,a9,a2,a9,a2,a9)
*cfclos

alls

!Makro Aufrufe

test,70
test,71
test,72
test,73

alls

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ich habe da eine Ahnung (probiert habe ich es nicht). Die Ansys-Hilfe sagt zu *vwrite:

Zitat:

---

For array parameter items, you must define the starting array element number. Looping continues (incrementing the vector index number of each array parameter by one) each time you output a line, until the maximum array vector element is written.

---

Entweder, du verwendest also vorher den Befehl *vlen oder du verwendest die folgenden Zeilen zur Ausgabe (ich weiß, ist nicht schön...):

Code:

---

delta1 = delta(1)
delta2 = delta(2)
delta3 = delta(3)
*cfopen,frank,txt,,append ! öffnet das File auswertung.txt und hängt die Daten weiter an

*vwrite,%arg1%,'  ',delta1,'  ',delta2,'  ',delta3
(F9.0,a2,F9.4,a2,F9.4,a2,F9.4)

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo ChristopN

Genau richtig, Danke! Dein Code passt.

Grues Frank

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP